blob: 3bef6659735313e91ce5ddb3368adf36c3d52e8f (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
{
stdenv, python2Packages, openssl,
# Many Salt modules require various Python modules to be installed,
# passing them in this array enables Salt to find them.
extraInputs ? []
}:
let
# Use tornado-4.x until https://github.com/saltstack/salt/issues/45790 is resolved
tornado = python2Packages.tornado.overridePythonAttrs (oldAttrs: rec {
version = "4.5.3";
name = "${oldAttrs.pname}-${version}";
src = oldAttrs.src.override {
inherit version;
sha256 = "02jzd23l4r6fswmwxaica9ldlyc2p6q8dk6dyff7j58fmdzf853d";
};
});
in
python2Packages.buildPythonApplication rec {
pname = "salt";
version = "2017.7.4";
src = python2Packages.fetchPypi {
inherit pname version;
sha256 = "15xfvclk3ns8vk17j7bfy4alq7ab5x3y3jnpqzp5583bfyak0mqx";
};
propagatedBuildInputs = with python2Packages; [
futures
jinja2
markupsafe
msgpack-python
pycrypto
pyyaml
pyzmq
requests
tornado
] ++ extraInputs;
patches = [ ./fix-libcrypto-loading.patch ];
postPatch = ''
substituteInPlace "salt/utils/rsax931.py" \
--subst-var-by "libcrypto" "${openssl.out}/lib/libcrypto.so"
'';
# The tests fail due to socket path length limits at the very least;
# possibly there are more issues but I didn't leave the test suite running
# as is it rather long.
doCheck = false;
meta = with stdenv.lib; {
homepage = https://saltstack.com/;
description = "Portable, distributed, remote execution and configuration management system";
maintainers = with maintainers; [ aneeshusa ];
license = licenses.asl20;
};
}
|