blob: 09910f125bc48e47e2c5718d19e8ed69c4324757 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
{ lib
, python3
, fetchPypi
, groff
, less
, nix-update-script
, testers
, awscli
}:
python3.pkgs.buildPythonApplication rec {
pname = "awscli";
version = "1.32.58"; # N.B: if you change this, change botocore and boto3 to a matching version too
pyproject = true;
src = fetchPypi {
inherit pname version;
hash = "sha256-dffY/BKsQ7vztW2sGn+WaZB0fXnqwwVjA4nkVwRZ1js=";
};
nativeBuildInputs = [
python3.pkgs.pythonRelaxDepsHook
];
pythonRelaxDeps = [
"colorama"
"docutils"
"rsa"
];
build-system = [
python3.pkgs.setuptools
];
propagatedBuildInputs = with python3.pkgs; [
botocore
s3transfer
colorama
docutils
rsa
pyyaml
groff
less
];
postInstall = ''
mkdir -p $out/share/bash-completion/completions
echo "complete -C $out/bin/aws_completer aws" > $out/share/bash-completion/completions/awscli
mkdir -p $out/share/zsh/site-functions
mv $out/bin/aws_zsh_completer.sh $out/share/zsh/site-functions
rm $out/bin/aws.cmd
'';
doInstallCheck = true;
installCheckPhase = ''
runHook preInstallCheck
$out/bin/aws --version | grep "${python3.pkgs.botocore.version}"
$out/bin/aws --version | grep "${version}"
runHook postInstallCheck
'';
passthru = {
python = python3; # for aws_shell
updateScript = nix-update-script {
# Excludes 1.x versions from the Github tags list
extraArgs = [ "--version-regex" "^(1\.(.*))" ];
};
tests.version = testers.testVersion {
package = awscli;
command = "aws --version";
inherit version;
};
};
meta = with lib; {
homepage = "https://aws.amazon.com/cli/";
changelog = "https://github.com/aws/aws-cli/blob/${version}/CHANGELOG.rst";
description = "Unified tool to manage your AWS services";
license = licenses.asl20;
mainProgram = "aws";
maintainers = with maintainers; [ anthonyroussel ];
};
}
|