blob: f244031f05906a85b6135a2a9a6c49a40d7b6697 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
{ lib, stdenvNoCC, fetchurl, makeBinaryWrapper, jre, version, hash }:
stdenvNoCC.mkDerivation {
pname = "papermc";
inherit version;
src =
let
version-split = lib.strings.splitString "-" version;
mcVersion = builtins.elemAt version-split 0;
buildNum = builtins.elemAt version-split 1;
in
fetchurl {
url = "https://papermc.io/api/v2/projects/paper/versions/${mcVersion}/builds/${buildNum}/downloads/paper-${version}.jar";
inherit hash;
};
installPhase = ''
runHook preInstall
install -D $src $out/share/papermc/papermc.jar
makeWrapper ${lib.getExe jre} "$out/bin/minecraft-server" \
--append-flags "-jar $out/share/papermc/papermc.jar nogui"
runHook postInstall
'';
nativeBuildInputs = [
makeBinaryWrapper
];
dontUnpack = true;
preferLocalBuild = true;
allowSubstitutes = false;
passthru = {
updateScript = ./update.py;
};
meta = {
description = "High-performance Minecraft Server";
homepage = "https://papermc.io/";
sourceProvenance = with lib.sourceTypes; [ binaryBytecode ];
license = lib.licenses.gpl3Only;
platforms = lib.platforms.unix;
maintainers = with lib.maintainers; [ aaronjanse neonfuz MayNiklas ];
mainProgram = "minecraft-server";
};
}
|