blob: 5a7ca869278afbfc154e2a3cffd6ed6cce60a837 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
{ lib
, stdenv
, fetchzip
, texliveMedium
, buildDocs ? false
}:
stdenv.mkDerivation (finalAttrs: {
pname = "asl";
version = "142-bld232";
src = let inherit (finalAttrs) pname version; in fetchzip {
name = "${pname}-${version}";
url = "http://john.ccac.rwth-aachen.de:8000/ftp/as/source/c_version/asl-current-${version}.tar.bz2";
hash = "sha256-Q50GzXBxFMhbt5s9OgHPNH4bdqz2hhEmTnMmKowVn2E=";
};
outputs = [ "out" "doc" "man" ];
nativeBuildInputs = lib.optionals buildDocs [ texliveMedium ];
postPatch = lib.optionalString (!buildDocs) ''
substituteInPlace Makefile --replace "all: binaries docs" "all: binaries"
'' + lib.optionalString (stdenv.isDarwin && stdenv.isAarch64) ''
substituteInPlace sysdefs.h --replace "x86_64" "aarch64"
'';
dontConfigure = true;
preBuild = ''
bindir="${placeholder "out"}/bin" \
docdir="${placeholder "doc"}/share/doc/asl" \
incdir="${placeholder "out"}/include/asl" \
libdir="${placeholder "out"}/lib/asl" \
mandir="${placeholder "man"}/share/man" \
substituteAll ${./Makefile-nixos.def} Makefile.def
mkdir -p .objdir
'';
meta = with lib; {
homepage = "http://john.ccac.rwth-aachen.de:8000/as/index.html";
description = "Portable macro cross assembler";
longDescription = ''
AS is a portable macro cross assembler for a variety of microprocessors
and -controllers. Though it is mainly targeted at embedded processors and
single-board computers, you also find CPU families in the target list that
are used in workstations and PCs.
'';
license = licenses.gpl2Plus;
maintainers = with maintainers; [ AndersonTorres ];
platforms = platforms.unix;
};
})
# TODO: cross-compilation support
# TODO: customize TeX input
# TODO: report upstream about `mkdir -p .objdir/`
# TODO: suggest upstream about building docs as an option
|