blob: cc97be1c687492a6d2d928437af201c008abdebd (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
{ lib, stdenv, fetchFromGitHub, fetchpatch, cmake, boost, catch2_3, libcpr, trompeloeil }:
stdenv.mkDerivation (finalAttrs: {
pname = "influxdb-cxx";
version = "0.7.2";
src = fetchFromGitHub {
owner = "offa";
repo = "influxdb-cxx";
rev = "v${finalAttrs.version}";
hash = "sha256-DFslPrbgqS3JGx62oWlsC+AN5J2CsFjGcDaDRCadw7E=";
};
patches = [
# Fix unclosed test case tag
(fetchpatch {
url = "https://github.com/offa/influxdb-cxx/commit/b31f94982fd1d50e89ce04f66c694bec108bf470.patch";
hash = "sha256-oSdpNlWV744VpzfiWzp0ziNKaReLTlyfJ+SF2qyH+TU=";
})
];
postPatch = ''
substituteInPlace CMakeLists.txt --replace "-Werror" ""
'';
nativeBuildInputs = [ cmake ];
buildInputs = [ boost libcpr ]
++ lib.optionals finalAttrs.doCheck [ catch2_3 trompeloeil ];
cmakeFlags = [
(lib.cmakeBool "INFLUXCXX_TESTING" finalAttrs.doCheck)
(lib.cmakeFeature "CMAKE_CTEST_ARGUMENTS" "-E;BoostSupportTest") # requires network access
];
doCheck = true;
meta = with lib; {
description = "InfluxDB C++ client library";
homepage = "https://github.com/offa/influxdb-cxx";
license = licenses.mit;
maintainers = with maintainers; [ sikmir ];
platforms = platforms.unix;
};
})
|