pkgs/applications/networking/instant-messengers/matrique/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{ stdenv, fetchFromGitLab, fetchFromGitHub, qmake
, qtquickcontrols2, qtmultimedia, qtgraphicaleffects
, libqmatrixclient
}:

let

  libqmatrixclient_git = libqmatrixclient.overrideDerivation (oldAttrs: {
    name = "libqmatrixclient-git-for-matrique";
    src = fetchFromGitHub {
      owner = "QMatrixClient";
      repo = "libqmatrixclient";
      rev = "d9ff200f";
      sha256 = "0qxkffg1499wnn8rbndq6z51sz6hiij2pkp40cvs530sl0zg0c69";
    };
  });

  SortFilterProxyModel = fetchFromGitLab {
    owner = "b0";
    repo = "SortFilterProxyModel";
    rev = "3c2c125c";
    sha256 = "1494dvq7kiq0ymf5f9hr47pw80zv3m3dncnaw1pnzs7mhkf2s5fr";
  };

in stdenv.mkDerivation rec {
  name = "matrique-${version}";
  version = "250";

  src = fetchFromGitLab {
    owner = "b0";
    repo = "matrique";
    rev = version;
    sha256 = "0l7ag2q3l8ixczwc43igvkkl81g5s5j032gzizmgpzb1bjpdgry7";
  };

  postPatch = ''
    rm -r include/*
    ln -sf ${libqmatrixclient_git.src} include/libqmatrixclient
    ln -sf ${SortFilterProxyModel} include/SortFilterProxyModel
  '';

  nativeBuildInputs = [ qmake ];
  buildInputs = [
    qtquickcontrols2 qtmultimedia qtgraphicaleffects
    libqmatrixclient_git
  ];

  meta = with stdenv.lib; {
    inherit (src.meta) homepage;
    description = "A glossy client for Matrix";
    maintainers = with maintainers; [ fpletz ];
    license = licenses.gpl3;
    platforms = platforms.linux;
  };
}