blob: 79353f1776adfb3f57cb6073adf49b6c13fbb6c2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
|
self: super:
let
mkGitEmacs = namePrefix: jsonFile: { ... }@args:
let
repoMeta = super.lib.importJSON jsonFile;
fetcher =
if repoMeta.type == "savannah" then
super.fetchFromSavannah
else if repoMeta.type == "github" then
super.fetchFromGitHub
else
throw "Unknown repository type ${repoMeta.type}!";
in
builtins.foldl'
(drv: fn: fn drv)
super.emacs
([
(drv: drv.override ({ srcRepo = true; } // builtins.removeAttrs args [ "noTreeSitter" "treeSitterPlugins" ]))
(
drv: drv.overrideAttrs (
old: {
name = "${namePrefix}-${repoMeta.version}";
inherit (repoMeta) version;
src = fetcher (builtins.removeAttrs repoMeta [ "type" "version" ]);
patches = [ ];
# fixes segfaults that only occur on aarch64-linux (#264)
configureFlags = old.configureFlags ++
super.lib.optionals (super.stdenv.isLinux && super.stdenv.isAarch64)
[ "--enable-check-lisp-object-type" ];
postPatch = old.postPatch + ''
substituteInPlace lisp/loadup.el \
--replace '(emacs-repository-get-version)' '"${repoMeta.rev}"' \
--replace '(emacs-repository-get-branch)' '"master"'
'' +
# XXX: Maybe remove when emacsLsp updates to use Emacs
# 29. We already have logic in upstream Nixpkgs to use
# a different patch for earlier major versions of Emacs,
# but the major version for emacsLsp follows the format
# of version YYYYMMDD, as opposed to version (say) 29.
# Removing this here would also require that we don't
# overwrite the patches attribute in the overlay to an
# empty list since we would then expect the Nixpkgs
# patch to be used. Not sure if it's better to rely on
# upstream Nixpkgs since it's cumbersome to wait for
# things to get merged into master.
(super.lib.optionalString (old ? NATIVE_FULL_AOT)
(let backendPath = (super.lib.concatStringsSep " "
(builtins.map (x: ''\"-B${x}\"'') ([
# Paths necessary so the JIT compiler finds its libraries:
"${super.lib.getLib self.libgccjit}/lib"
"${super.lib.getLib self.libgccjit}/lib/gcc"
"${super.lib.getLib self.stdenv.cc.libc}/lib"
] ++ super.lib.optionals (self.stdenv.cc?cc.libgcc) [
"${super.lib.getLib self.stdenv.cc.cc.libgcc}/lib"
] ++ [
# Executable paths necessary for compilation (ld, as):
"${super.lib.getBin self.stdenv.cc.cc}/bin"
"${super.lib.getBin self.stdenv.cc.bintools}/bin"
"${super.lib.getBin self.stdenv.cc.bintools.bintools}/bin"
])));
in ''
substituteInPlace lisp/emacs-lisp/comp.el --replace \
"(defcustom comp-libgccjit-reproducer nil" \
"(setq native-comp-driver-options '(${backendPath}))
(defcustom comp-libgccjit-reproducer nil"
''));
}
)
)
# reconnect pkgs to the built emacs
(
drv:
let
result = drv.overrideAttrs (old: {
passthru = old.passthru // {
pkgs = self.emacsPackagesFor result;
};
});
in
result
)
]
++ (super.lib.optional (! (args ? "noTreeSitter")) (
drv: drv.overrideAttrs (old:
let
libName = drv: super.lib.removeSuffix "-grammar" drv.pname;
libSuffix = if super.stdenv.isDarwin then "dylib" else "so";
lib = drv: ''lib${libName drv}.${libSuffix}'';
linkCmd = drv:
if super.stdenv.isDarwin
then ''cp ${drv}/parser .
chmod +w ./parser
install_name_tool -id $out/lib/${lib drv} ./parser
cp ./parser $out/lib/${lib drv}
${self.pkgs.darwin.sigtool}/bin/codesign -s - -f $out/lib/${lib drv}
''
else ''ln -s ${drv}/parser $out/lib/${lib drv}'';
plugins = args.treeSitterPlugins;
tree-sitter-grammars = super.runCommandCC "tree-sitter-grammars" {}
(super.lib.concatStringsSep "\n" (["mkdir -p $out/lib"] ++ (map linkCmd plugins)));
in {
buildInputs = old.buildInputs ++ [ self.pkgs.tree-sitter tree-sitter-grammars ];
buildFlags = super.lib.optionalString self.stdenv.isDarwin
"LDFLAGS=-Wl,-rpath,${super.lib.makeLibraryPath [tree-sitter-grammars]}";
TREE_SITTER_LIBS = "-ltree-sitter";
# Add to list of directories dlopen/dynlib_open searches for tree sitter languages *.so
postFixup = old.postFixup + super.lib.optionalString self.stdenv.isLinux ''
${self.pkgs.patchelf}/bin/patchelf --add-rpath ${super.lib.makeLibraryPath [ tree-sitter-grammars ]} $out/bin/emacs
'';
}
)
)));
defaultTreeSitterPlugins = with self.pkgs.tree-sitter-grammars; [
tree-sitter-bash
tree-sitter-c
tree-sitter-c-sharp
tree-sitter-cmake
tree-sitter-cpp
tree-sitter-css
tree-sitter-dockerfile
tree-sitter-go
tree-sitter-gomod
tree-sitter-html
tree-sitter-java
tree-sitter-javascript
tree-sitter-json
tree-sitter-python
tree-sitter-ruby
tree-sitter-rust
tree-sitter-toml
tree-sitter-tsx
tree-sitter-typescript
tree-sitter-yaml
];
emacsGit = (super.lib.makeOverridable (mkGitEmacs "emacs-git" ../repos/emacs/emacs-master.json) { withSQLite3 = true; withWebP = true; treeSitterPlugins = defaultTreeSitterPlugins; }).overrideAttrs (
oa: {
patches = oa.patches ++ [
# XXX: #318
./bytecomp-revert.patch
]; }
);
emacsPgtk = (super.lib.makeOverridable (mkGitEmacs "emacs-pgtk" ../repos/emacs/emacs-master.json) { withSQLite3 = true; withWebP = true; withPgtk = true; treeSitterPlugins = defaultTreeSitterPlugins; }).overrideAttrs (
oa: {
patches = oa.patches ++ [
# XXX: #318
./bytecomp-revert.patch
]; }
);
emacsUnstable = super.lib.makeOverridable (mkGitEmacs "emacs-unstable" ../repos/emacs/emacs-unstable.json) { withSQLite3 = true; withWebP = true; treeSitterPlugins = defaultTreeSitterPlugins; };
emacsUnstablePgtk = super.lib.makeOverridable (mkGitEmacs "emacs-unstable" ../repos/emacs/emacs-unstable.json) { withSQLite3 = true; withWebP = true; withPgtk = true; treeSitterPlugins = defaultTreeSitterPlugins; };
emacsLsp = (mkGitEmacs "emacs-lsp" ../repos/emacs/emacs-lsp.json { noTreeSitter = true; });
in
{
inherit emacsGit emacsUnstable;
inherit emacsPgtk emacsUnstablePgtk;
emacsGit-nox = (
(
emacsGit.override {
withNS = false;
withX = false;
withGTK2 = false;
withGTK3 = false;
withWebP = false;
}
).overrideAttrs (
oa: {
name = "${oa.name}-nox";
}
)
);
emacsUnstable-nox = (
(
emacsUnstable.override {
withNS = false;
withX = false;
withGTK2 = false;
withGTK3 = false;
withWebP = false;
}
).overrideAttrs (
oa: {
name = "${oa.name}-nox";
}
)
);
inherit emacsLsp;
emacsWithPackagesFromUsePackage = import ../elisp.nix { pkgs = self; };
emacsWithPackagesFromPackageRequires = import ../packreq.nix { pkgs = self; };
} // super.lib.optionalAttrs (super.config.allowAliases or true) {
emacsGcc = builtins.trace "emacsGcc has been renamed to emacsGit, please update your expression." emacsGit;
emacsGitNativeComp = builtins.trace "emacsGitNativeComp has been renamed to emacsGit, please update your expression." emacsGit;
emacsGitTreeSitter = builtins.trace "emacsGitTreeSitter has been renamed to emacsGit, please update your expression." emacsGit;
emacsNativeComp = builtins.trace "emacsNativeComp has been renamed to emacsUnstable, please update your expression." emacsUnstable;
emacsPgtkGcc = builtins.trace "emacsPgtkGcc has been renamed to emacsPgtk, please update your expression." emacsPgtk;
emacsPgtkNativeComp = builtins.trace "emacsPgtkNativeComp has been renamed to emacsPgtk, please update your expression." emacsPgtk;
}
|