blob: ed4f25c31afbc356a431d08a644e12ef165bfdfc (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
{ stdenv, fetchFromGitLab, fetchpatch
, getopt, lua, boost, pkgconfig, swig, perl, gcc }:
with stdenv.lib;
perl.pkgs.toPerlModule (stdenv.mkDerivation rec {
pname = "highlight";
version = "3.53";
src = fetchFromGitLab {
owner = "saalen";
repo = "highlight";
rev = "v${version}";
sha256 = "11szws4q6qyffq2fsvh1vksh1d0kcwg6smyyba9yr61hzx6zmzgr";
};
enableParallelBuilding = true;
nativeBuildInputs = [ pkgconfig swig perl ] ++ optional stdenv.isDarwin gcc;
buildInputs = [ getopt lua boost ];
prePatch = stdenv.lib.optionalString stdenv.cc.isClang ''
substituteInPlace src/makefile \
--replace 'CXX=g++' 'CXX=clang++'
'';
patches = [
(fetchpatch {
url = "https://gitlab.com/saalen/highlight/commit/a6e9f5b28cdfee7141847e3b1bc392ff06be615d.patch";
sha256 = "0rjs1009a0x8bw0nzr05fn5a7df32h5y7r6691blkp2x6iw21nz2";
})
];
preConfigure = ''
makeFlags="PREFIX=$out conf_dir=$out/etc/highlight/ CXX=$CXX AR=$AR"
'';
# This has to happen _before_ the main build because it does a
# `make clean' for some reason.
preBuild = ''
make -C extras/swig $makeFlags perl
'';
doCheck = true;
postCheck = ''
perl -Iextras/swig extras/swig/testmod.pl
'';
preInstall = ''
mkdir -p $out/${perl.libPrefix}
install -m644 extras/swig/highlight.{so,pm} $out/${perl.libPrefix}
make -C extras/swig clean # Clean up intermediate files.
'';
meta = with stdenv.lib; {
description = "Source code highlighting tool";
homepage = "http://www.andre-simon.de/doku/highlight/en/highlight.php";
platforms = platforms.unix;
maintainers = with maintainers; [ ndowens willibutz ];
};
})
|