1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
|
{ lib
, stdenv
, fetchFromGitHub
, autoreconfHook
, libewf
, afflib
, openssl
, zlib
, openjdk
, perl
, ant
}:
stdenv.mkDerivation rec {
version = "4.12.1";
pname = "sleuthkit";
sleuthsrc = fetchFromGitHub {
owner = "sleuthkit";
repo = "sleuthkit";
rev = "${pname}-${version}";
hash = "sha256-q51UY2lIcLijycNaq9oQIwUXpp/1mfc3oPN4syOPF44=";
};
# Fetch libraries using a fixed output derivation
rdeps = stdenv.mkDerivation rec {
version = "1.0";
pname = "sleuthkit-deps";
nativeBuildInputs = [
openjdk
ant
];
src = sleuthsrc;
# unpack, build, install
dontConfigure = true;
buildPhase = ''
export IVY_HOME=$NIX_BUILD_TOP/.ant
pushd bindings/java
ant retrieve-deps
popd
pushd case-uco/java
ant get-ivy-dependencies
popd
'';
installPhase = ''
export IVY_HOME=$NIX_BUILD_TOP/.ant
mkdir -m 755 -p $out/bindings/java
cp -r bindings/java/lib $out/bindings/java
mkdir -m 755 -p $out/case-uco/java
cp -r case-uco/java/lib $out/case-uco/java
cp -r $IVY_HOME/lib $out
chmod -R 755 $out/lib
'';
outputHashMode = "recursive";
outputHash = "0fq7v6zlgybg4v6k9wqjlk4gaqgjrpihbnr182vaqriihflav2s8";
outputHashAlgo = "sha256";
};
src = sleuthsrc;
postPatch = ''
substituteInPlace tsk/img/ewf.cpp --replace libewf_handle_read_random libewf_handle_read_buffer_at_offset
'';
enableParallelBuilding = true;
nativeBuildInputs = [
autoreconfHook
openjdk
perl
ant
rdeps
];
buildInputs = [
libewf
afflib
openssl
zlib
];
# Hack to fix the RPATH
preFixup = ''
rm -rf */.libs
'';
postUnpack = ''
export IVY_HOME="$NIX_BUILD_TOP/.ant"
export JAVA_HOME="${openjdk}"
export ant_args="-Doffline=true -Ddefault-jar-location=$IVY_HOME/lib"
# pre-positioning these jar files allows -Doffline=true to work
mkdir -p source/{bindings,case-uco}/java $IVY_HOME
cp -r ${rdeps}/bindings/java/lib source/bindings/java
chmod -R 755 source/bindings/java
cp -r ${rdeps}/case-uco/java/lib source/case-uco/java
chmod -R 755 source/case-uco/java
cp -r ${rdeps}/lib $IVY_HOME
chmod -R 755 $IVY_HOME
'';
meta = with lib; {
description = "A forensic/data recovery tool";
homepage = "https://www.sleuthkit.org/";
changelog = "https://github.com/sleuthkit/sleuthkit/releases/tag/sleuthkit-${version}";
maintainers = with maintainers; [ raskin gfrascadorio ];
platforms = platforms.linux;
sourceProvenance = with sourceTypes; [
fromSource
binaryBytecode # dependencies
];
license = licenses.ipl10;
};
}
|