blob: cff903021591a1d456223c3f60065a556645298c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
{ buildGoModule
, fetchFromGitHub
, lib
}:
let
inherit (lib) concatStringsSep concatMap id mapAttrsToList;
in
buildGoModule rec {
pname = "pomerium-cli";
version = "0.22.0";
src = fetchFromGitHub {
owner = "pomerium";
repo = "cli";
rev = "v${version}";
sha256 = "sha256-0vRLjmzW/U/Kssu4VQO6mFqVH4UovmTGEEfxeWI8Nqo=";
};
vendorHash = "sha256-dnfJnndYXR6LQKDruLSsDav4DtyaGu5/rNnk69oMhPU=";
subPackages = [
"cmd/pomerium-cli"
];
ldflags = let
# Set a variety of useful meta variables for stamping the build with.
setVars = {
"github.com/pomerium/cli/version" = {
Version = "v${version}";
BuildMeta = "nixpkgs";
ProjectName = "pomerium-cli";
ProjectURL = "github.com/pomerium/cli";
};
};
concatStringsSpace = list: concatStringsSep " " list;
mapAttrsToFlatList = fn: list: concatMap id (mapAttrsToList fn list);
varFlags = concatStringsSpace (
mapAttrsToFlatList (package: packageVars:
mapAttrsToList (variable: value:
"-X ${package}.${variable}=${value}"
) packageVars
) setVars);
in [
"${varFlags}"
];
installPhase = ''
runHook preInstall
install -Dm0755 $GOPATH/bin/pomerium-cli $out/bin/pomerium-cli
runHook postInstall
'';
meta = with lib; {
homepage = "https://pomerium.io";
description = "Client-side helper for Pomerium authenticating reverse proxy";
mainProgram = "pomerium-cli";
license = licenses.asl20;
maintainers = with maintainers; [ lukegb ];
platforms = platforms.unix;
};
}
|