blob: e0b24a4e70ddcd2bf93d4fbdc2c71918b069b33e (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
{
buildEnv,
lib,
man,
nixos,
# TODO: replace indirect self-reference by proper self-reference
# https://github.com/NixOS/nixpkgs/pull/119942
nixos-install-tools,
runCommand,
nixosTests,
}:
let
inherit (nixos {}) config;
version = config.system.nixos.version;
in
(buildEnv {
name = "nixos-install-tools-${version}";
paths = lib.attrValues {
# See nixos/modules/installer/tools/tools.nix
inherit (config.system.build)
nixos-install nixos-generate-config nixos-enter;
inherit (config.system.build.manual) nixos-configuration-reference-manpage;
};
extraOutputsToInstall = ["man"];
meta = {
description = "The essential commands from the NixOS installer as a package";
longDescription = ''
With this package, you get the commands like nixos-generate-config and
nixos-install that you would otherwise only find on a NixOS system, such
as an installer image.
This way, you can install NixOS using a machine that only has Nix.
'';
license = lib.licenses.mit;
homepage = "https://nixos.org";
platforms = lib.platforms.linux;
};
passthru.tests = {
nixos-tests = lib.recurseIntoAttrs nixosTests.installer;
nixos-install-help = runCommand "test-nixos-install-help" {
nativeBuildInputs = [
man
nixos-install-tools
];
meta.description = ''
Make sure that --help works. It's somewhat non-trivial because it
requires man.
'';
} ''
nixos-install --help | grep -F 'NixOS Reference Pages'
nixos-install --help | grep -F 'configuration.nix'
nixos-generate-config --help | grep -F 'NixOS Reference Pages'
nixos-generate-config --help | grep -F 'hardware-configuration.nix'
# FIXME: Tries to call unshare, which it must not do for --help
# nixos-enter --help | grep -F 'NixOS Reference Pages'
touch $out
'';
};
}).overrideAttrs {
inherit version;
pname = "nixos-install-tools";
}
|