1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
{ lib
, buildPythonPackage
, fetchPypi
, brotli
, hatchling
, certifi
, ffmpeg
, rtmpdump
, atomicparsley
, pycryptodomex
, websockets
, mutagen
, requests
, secretstorage
, urllib3
, atomicparsleySupport ? true
, ffmpegSupport ? true
, rtmpSupport ? true
, withAlias ? false # Provides bin/youtube-dl for backcompat
, update-python-libraries
}:
buildPythonPackage rec {
pname = "yt-dlp";
# The websites yt-dlp deals with are a very moving target. That means that
# downloads break constantly. Because of that, updates should always be backported
# to the latest stable release.
version = "2024.3.10";
pyproject = true;
src = fetchPypi {
inherit version;
pname = "yt_dlp";
hash = "sha256-bnTLFKadvrhyyO9OC4u+0u6EbsYzUTzzEkp0wfrtwHs=";
};
nativeBuildInputs = [
hatchling
];
propagatedBuildInputs = [
brotli
certifi
mutagen
pycryptodomex
requests
secretstorage # "optional", as in not in requirements.txt, needed for `--cookies-from-browser`
urllib3
websockets
];
# Ensure these utilities are available in $PATH:
# - ffmpeg: post-processing & transcoding support
# - rtmpdump: download files over RTMP
# - atomicparsley: embedding thumbnails
makeWrapperArgs =
let
packagesToBinPath = []
++ lib.optional atomicparsleySupport atomicparsley
++ lib.optional ffmpegSupport ffmpeg
++ lib.optional rtmpSupport rtmpdump;
in lib.optionals (packagesToBinPath != [])
[ ''--prefix PATH : "${lib.makeBinPath packagesToBinPath}"'' ];
setupPyBuildFlags = [
"build_lazy_extractors"
];
# Requires network
doCheck = false;
postInstall = lib.optionalString withAlias ''
ln -s "$out/bin/yt-dlp" "$out/bin/youtube-dl"
'';
passthru.updateScript = [ update-python-libraries (toString ./.) ];
meta = with lib; {
homepage = "https://github.com/yt-dlp/yt-dlp/";
description = "Command-line tool to download videos from YouTube.com and other sites (youtube-dl fork)";
longDescription = ''
yt-dlp is a youtube-dl fork based on the now inactive youtube-dlc.
youtube-dl is a small, Python-based command-line program
to download videos from YouTube.com and a few more sites.
youtube-dl is released to the public domain, which means
you can modify it, redistribute it or use it however you like.
'';
license = licenses.unlicense;
maintainers = with maintainers; [ mkg20001 SuperSandro2000 marsam ];
mainProgram = "yt-dlp";
};
}
|