blob: 58876d6789695efb1fe19602fb0a012bc8fea454 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
{ lib
, stdenv
, fetchFromGitHub
, ant
, jdk8 # the build script wants JAVA 8 for compilation
, jre # version can be >= 8 (latest version by default)
, makeWrapper
, makeDesktopItem
, copyDesktopItems
, stripJavaArchivesHook
}:
stdenv.mkDerivation (finalAttrs: {
pname = "jpsxdec";
version = "2.0";
src = fetchFromGitHub {
owner = "m35";
repo = "jpsxdec";
rev = "v${finalAttrs.version}";
hash = "sha256-PZOc5mpnUiUyydWyfZjWuPG4w+tRd6WLJ6YQMqu/95I=";
};
sourceRoot = "${finalAttrs.src.name}/jpsxdec";
nativeBuildInputs = [
ant
jdk8
makeWrapper
copyDesktopItems
stripJavaArchivesHook
];
buildPhase = ''
runHook preBuild
ant release
runHook postBuild
'';
installPhase = ''
runHook preInstall
mkdir -p $out/share/jpsxdec
mv _ant/release/{doc,*.jar} $out/share/jpsxdec
install -Dm644 src/jpsxdec/gui/icon48.png $out/share/pixmaps/jpsxdec.png
makeWrapper ${jre}/bin/java $out/bin/jpsxdec \
--add-flags "-jar $out/share/jpsxdec/jpsxdec.jar"
runHook postInstall
'';
desktopItems = [
(makeDesktopItem {
name = "jpsxdec";
exec = "jpsxdec";
icon = "jpsxdec";
desktopName = "jPSXdec";
comment = finalAttrs.meta.description;
categories = [ "AudioVideo" "Utility" ];
})
];
meta = with lib; {
changelog = "https://github.com/m35/jpsxdec/blob/${finalAttrs.src.rev}/jpsxdec/doc/CHANGES.txt";
description = "Cross-platform PlayStation 1 audio and video converter";
homepage = "https://jpsxdec.blogspot.com/";
license = {
url = "https://raw.githubusercontent.com/m35/jpsxdec/${finalAttrs.src.rev}/.github/LICENSE.md";
free = true;
};
mainProgram = "jpsxdec";
maintainers = with maintainers; [ zane ];
platforms = platforms.all;
};
})
|