blob: 9988029f1f776f495ba34421d89fdc072272158c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
{ lib
, stdenv
, python3
, fetchpatch
, fetchPypi
, openssl
# Many Salt modules require various Python modules to be installed,
# passing them in this array enables Salt to find them.
, extraInputs ? []
}:
python3.pkgs.buildPythonApplication rec {
pname = "salt";
version = "3006.7";
format = "setuptools";
src = fetchPypi {
inherit pname version;
hash = "sha256-7ZLSG4TrnUefk7qJRoRTQIEX4NwQEGFCFJmejQwhCv0=";
};
patches = [
# https://github.com/saltstack/salt/pull/63795
(fetchpatch {
name = "remove-duplicate-scripts.patch";
url = "https://github.com/saltstack/salt/commit/6b9463836e70e40409dbf653f01aa94ef869dfe7.patch";
hash = "sha256-VcVdKC8EH4qoWHtq6eEPl8OviR4eA2k/S2lWNQbubJw=";
})
./fix-libcrypto-loading.patch
];
postPatch = ''
substituteInPlace "salt/utils/rsax931.py" \
--subst-var-by "libcrypto" "${lib.getLib openssl}/lib/libcrypto${stdenv.hostPlatform.extensions.sharedLibrary}"
substituteInPlace requirements/base.txt \
--replace contextvars ""
# Don't require optional dependencies on Darwin, let's use
# `extraInputs` like on any other platform
echo -n > "requirements/darwin.txt"
# Remove windows-only requirement
substituteInPlace "requirements/zeromq.txt" \
--replace 'pyzmq==25.0.2 ; sys_platform == "win32"' ""
'';
propagatedBuildInputs = with python3.pkgs; [
distro
jinja2
jmespath
looseversion
markupsafe
msgpack
packaging
psutil
pycryptodomex
pyyaml
pyzmq
requests
] ++ extraInputs;
# Don't use fixed dependencies on Darwin
USE_STATIC_REQUIREMENTS = "0";
# The tests fail due to socket path length limits at the very least;
# possibly there are more issues but I didn't leave the test suite running
# as is it rather long.
doCheck = false;
meta = with lib; {
homepage = "https://saltproject.io/";
changelog = "https://docs.saltproject.io/en/latest/topics/releases/${version}.html";
description = "Portable, distributed, remote execution and configuration management system";
maintainers = with maintainers; [ Flakebi ];
license = licenses.asl20;
};
}
|