blob: ad95c1cf3d689a634d488fb2a78e9931b79124e9 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
|
{ lib
, buildGoModule
, fetchFromGitHub
, buildNpmPackage
}:
let
version = "0.4.10";
src = fetchFromGitHub {
owner = "zinclabs";
repo = "zincsearch";
rev = "v${version}";
hash = "sha256-lScwnmu4hM78Va7Yi5HA0E5f2WQXrZaeqjRYJYxnQ5E=";
};
webui = buildNpmPackage {
inherit src version;
pname = "zinc-ui";
sourceRoot = "${src.name}/web";
npmDepsHash = "sha256-2AjUaEOn2Tj+X4f42SvNq1kX07WxkB1sl5KtGdCjbdw=";
env = {
CYPRESS_INSTALL_BINARY = 0; # cypress tries to download binaries otherwise
};
installPhase = ''
mkdir -p $out/share
mv dist $out/share/zinc-ui
'';
};
in
buildGoModule rec {
pname = "zincsearch";
inherit src version;
preBuild = ''
cp -r ${webui}/share/zinc-ui web/dist
'';
vendorHash = "sha256-SZG5/ISGblpcwwR/HOKxFl9SthXpE+IYS0S+4HYtHos=";
subPackages = [ "cmd/zincsearch" ];
ldflags = [
"-s"
"-w"
"-X github.com/zinclabs/zincsearch/pkg/meta.Version=${version}"
];
meta = with lib; {
description = "A lightweight alternative to elasticsearch that requires minimal resources, written in Go";
mainProgram = "zincsearch";
homepage = "https://zincsearch-docs.zinc.dev/";
license = licenses.asl20;
maintainers = with maintainers; [ dit7ya ];
};
}
|