blob: faa42933facdd9f1efc7e926d97d25259f786bb6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
{ lib
, buildGoModule
, fetchFromGitHub
, grafana-agent
, nixosTests
, stdenv
, systemd
, testers
}:
buildGoModule rec {
pname = "grafana-agent";
version = "0.35.4";
src = fetchFromGitHub {
owner = "grafana";
repo = "agent";
rev = "v${version}";
hash = "sha256-3pUKqmqnRm3/e/fhAV5cq16wcK/f7KWb3aoFbPXCC3o=";
};
vendorHash = "sha256-vzrp20Mg6AA0h3+5+qbKRa7nhx/hgiIHG6RNXLATpHE=";
proxyVendor = true; # darwin/linux hash mismatch
ldflags = let
prefix = "github.com/grafana/agent/pkg/build";
in [
"-s" "-w"
# https://github.com/grafana/agent/blob/d672eba4ca8cb010ad8a9caef4f8b66ea6ee3ef2/Makefile#L125
"-X ${prefix}.Version=${version}"
"-X ${prefix}.Branch=v${version}"
"-X ${prefix}.Revision=v${version}"
"-X ${prefix}.BuildUser=nix"
"-X ${prefix}.BuildDate=1980-01-01T00:00:00Z"
];
tags = [
"nonetwork"
"nodocker"
"promtail_journal_enabled"
];
subPackages = [
"cmd/grafana-agent"
"cmd/grafana-agentctl"
];
# uses go-systemd, which uses libsystemd headers
# https://github.com/coreos/go-systemd/issues/351
env.NIX_CFLAGS_COMPILE = toString (lib.optionals stdenv.isLinux [ "-I${lib.getDev systemd}/include" ]);
# go-systemd uses libsystemd under the hood, which does dlopen(libsystemd) at
# runtime.
# Add to RUNPATH so it can be found.
postFixup = lib.optionalString stdenv.isLinux ''
patchelf \
--set-rpath "${lib.makeLibraryPath [ (lib.getLib systemd) ]}:$(patchelf --print-rpath $out/bin/grafana-agent)" \
$out/bin/grafana-agent
'';
passthru.tests = {
inherit (nixosTests) grafana-agent;
version = testers.testVersion {
inherit version;
command = "${lib.getExe grafana-agent} --version";
package = grafana-agent;
};
};
meta = {
description = "A lightweight subset of Prometheus and more, optimized for Grafana Cloud";
license = lib.licenses.asl20;
homepage = "https://grafana.com/products/cloud";
changelog = "https://github.com/grafana/agent/blob/${src.rev}/CHANGELOG.md";
maintainers = with lib.maintainers; [ flokli emilylange ];
mainProgram = "grafana-agent";
};
}
|