blob: 5540711f62c963f7b0b1d010992292dae309b9c8 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
{ lib, rustPlatform, fetchFromGitLab, pkg-config, sqlite, stdenv, darwin, nixosTests, rocksdb_6_23 }:
rustPlatform.buildRustPackage rec {
pname = "matrix-conduit";
version = "0.5.0";
src = fetchFromGitLab {
owner = "famedly";
repo = "conduit";
rev = "v${version}";
sha256 = "sha256-GSCpmn6XRbmnfH31R9c6QW3/pez9KHPjI99dR+ln0P4=";
};
# We have to use importCargoLock here because `cargo vendor` currently doesn't support workspace
# inheritance within Git dependencies, but importCargoLock does.
cargoLock = {
lockFile = ./Cargo.lock;
outputHashes = {
"heed-0.10.6" = "sha256-rm02pJ6wGYN4SsAbp85jBVHDQ5ITjZZd+79EC2ubRsY=";
"reqwest-0.11.9" = "sha256-wH/q7REnkz30ENBIK5Rlxnc1F6vOyuEANMHFmiVPaGw=";
"ruma-0.7.4" = "sha256-ztobLdOXSGyK1YcPMMIycO3ZmnjxG5mLkHltf0Fbs8s=";
};
};
# Conduit enables rusqlite's bundled feature by default, but we'd rather use our copy of SQLite.
preBuild = ''
substituteInPlace Cargo.toml --replace "features = [\"bundled\"]" "features = []"
cargo update --offline -p rusqlite
'';
nativeBuildInputs = [
rustPlatform.bindgenHook
pkg-config
];
buildInputs = [ sqlite ] ++ lib.optionals stdenv.isDarwin [
darwin.apple_sdk.frameworks.Security
];
ROCKSDB_INCLUDE_DIR = "${rocksdb_6_23}/include";
ROCKSDB_LIB_DIR = "${rocksdb_6_23}/lib";
# tests failed on x86_64-darwin with SIGILL: illegal instruction
doCheck = !(stdenv.isx86_64 && stdenv.isDarwin);
passthru.tests = {
inherit (nixosTests) matrix-conduit;
};
meta = with lib; {
description = "A Matrix homeserver written in Rust";
homepage = "https://conduit.rs/";
license = licenses.asl20;
maintainers = with maintainers; [ pstn piegames pimeys ];
mainProgram = "conduit";
};
}
|