blob: 5b1d8b0794d8035e21eba3a5baa7afdedec904b7 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
{ lib
, stdenv
, buildGoModule
, fetchFromGitHub
, gpgme
, lvm2
, btrfs-progs
, pkg-config
, go-md2man
, installShellFiles
, makeWrapper
, fuse-overlayfs
}:
buildGoModule rec {
pname = "skopeo";
version = "1.2.1";
src = fetchFromGitHub {
rev = "v${version}";
owner = "containers";
repo = "skopeo";
sha256 = "1y9pmijazbgxzriymrm7zrifmkd1x1wad9b3zjcj7zwr6c999dhg";
};
outputs = [ "out" "man" ];
vendorSha256 = null;
doCheck = false;
nativeBuildInputs = [ pkg-config go-md2man installShellFiles makeWrapper ];
buildInputs = [ gpgme ]
++ lib.optionals stdenv.isLinux [ lvm2 btrfs-progs ];
buildPhase = ''
patchShebangs .
make bin/skopeo docs
'';
installPhase = ''
install -Dm755 bin/skopeo -t $out/bin
installManPage docs/*.[1-9]
installShellCompletion --bash completions/bash/skopeo
'' + lib.optionalString stdenv.isLinux ''
wrapProgram $out/bin/skopeo \
--prefix PATH : ${lib.makeBinPath [ fuse-overlayfs ]}
'';
meta = with lib; {
description = "A command line utility for various operations on container images and image repositories";
homepage = "https://github.com/containers/skopeo";
maintainers = with maintainers; [ lewo ] ++ teams.podman.members;
license = licenses.asl20;
};
}
|