blob: d71b1e655d782adfb814cff7f08baddffe12cf7f (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
{ lib
, rustPlatform
, fetchFromGitHub
, runCommand
, stdenv
, patchelf
, zlib
, pkg-config
, openssl
, xz
, Security
}:
rustPlatform.buildRustPackage rec {
pname = "rustup-toolchain-install-master";
version = "1.7.3";
src = fetchFromGitHub {
owner = "kennytm";
repo = pname;
rev = "v${version}";
hash = "sha256-J25ER/g8Kylw/oTIEl4Gl8i1xmhR+4JM5M5EHpl1ras=";
};
cargoLock = {
lockFile = ./Cargo.lock;
};
patches =
let
patchelfPatch = runCommand "0001-dynamically-patchelf-binaries.patch" {
CC = stdenv.cc;
patchelf = patchelf;
libPath = "$ORIGIN/../lib:${lib.makeLibraryPath [ zlib ]}";
}
''
export dynamicLinker=$(cat $CC/nix-support/dynamic-linker)
substitute ${./0001-dynamically-patchelf-binaries.patch} $out \
--subst-var patchelf \
--subst-var dynamicLinker \
--subst-var libPath
'';
in
lib.optionals stdenv.isLinux [ patchelfPatch ];
nativeBuildInputs = [ pkg-config ];
buildInputs = [
openssl
xz
] ++ lib.optionals stdenv.isDarwin [
Security
];
# update Cargo.lock to work with openssl 3
postPatch = ''
ln -sf ${./Cargo.lock} Cargo.lock
'';
meta = with lib; {
description = "Install a rustc master toolchain usable from rustup";
mainProgram = "rustup-toolchain-install-master";
homepage = "https://github.com/kennytm/rustup-toolchain-install-master";
license = licenses.mit;
maintainers = with maintainers; [ davidtwco ];
};
}
|