nixpkgs/pkgs/development/tools/ronn/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40

{ stdenv, lib, bundlerEnv, bundlerUpdateScript, makeWrapper, groff, callPackage }:

stdenv.mkDerivation rec {
  pname = "ronn";
  version = env.gems.ronn-ng.version;

  env = bundlerEnv {
    name = "ronn-gems";
    gemdir = ./.;
  };

  dontUnpack = true;

  nativeBuildInputs = [
    makeWrapper
  ];

  installPhase = ''
    runHook preInstall

    mkdir -p $out/bin
    makeWrapper ${env}/bin/ronn $out/bin/ronn \
      --set PATH ${groff}/bin

    runHook postInstall
  '';

  passthru.updateScript = bundlerUpdateScript "ronn";

  passthru.tests.reproducible-html-manpage = callPackage ./test-reproducible-html.nix { };

  meta = with lib; {
    description = "markdown-based tool for building manpages";
    mainProgram = "ronn";
    homepage = "https://github.com/apjanke/ronn-ng";
    license = licenses.mit;
    maintainers = with maintainers; [ zimbatm nicknovitski ];
    platforms = env.ruby.meta.platforms;
  };
}