blob: 5cd6b423aa0c3e4cf20c1df628a12ec6e3030255 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
{ lib
, rustPlatform
, fetchFromGitHub
, stdenv
, darwin
}:
rustPlatform.buildRustPackage rec {
pname = "typst-lsp";
# Please update the corresponding vscode extension when updating
# this derivation.
version = "0.11.0";
src = fetchFromGitHub {
owner = "nvarner";
repo = "typst-lsp";
rev = "v${version}";
hash = "sha256-L0d+fDCLxU/XHC99VlIcZdiO3RohtWfoRnUPGIHodcc=";
};
cargoLock = {
lockFile = ./Cargo.lock;
outputHashes = {
"typst-0.9.0" = "sha256-LwRB/AQE8TZZyHEQ7kKB10itzEgYjg4R/k+YFqmutDc=";
"typst-syntax-0.7.0" = "sha256-yrtOmlFAKOqAmhCP7n0HQCOQpU3DWyms5foCdUb9QTg=";
"typstfmt_lib-0.2.6" = "sha256-UUVbnxIj7kQVpZvSbbB11i6wAvdTnXVk5cNSNoGBeRM=";
};
};
buildInputs = lib.optionals stdenv.isDarwin [
darwin.apple_sdk.frameworks.SystemConfiguration
];
checkFlags = [
# requires internet access
"--skip=workspace::package::external::remote_repo::test::full_download"
] ++ lib.optionals stdenv.isDarwin [
# both tests fail on darwin with 'Attempted to create a NULL object.'
"--skip=workspace::fs::local::test::read"
"--skip=workspace::package::external::manager::test::local_package"
];
# workspace::package::external::manager::test::local_package tries to access the data directory
preCheck = ''
export HOME=$(mktemp -d)
'';
meta = with lib; {
description = "A brand-new language server for Typst";
homepage = "https://github.com/nvarner/typst-lsp";
mainProgram = "typst-lsp";
changelog = "https://github.com/nvarner/typst-lsp/releases/tag/${src.rev}";
license = with licenses; [ asl20 mit ];
maintainers = with maintainers; [ figsoda GaetanLepage ];
};
}
|