blob: 4123ef3157dc7a67cca8891b2a6bb0fb47e9918b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
{ lib
, stdenv
, fetchFromGitHub
, rustPlatform
, coreutils
, installShellFiles
, libiconv
, mdbook
, nix-update-script
}:
rustPlatform.buildRustPackage rec {
pname = "just";
version = "1.25.0";
outputs = [ "out" "man" "doc" ];
src = fetchFromGitHub {
owner = "casey";
repo = pname;
rev = "refs/tags/${version}";
hash = "sha256-ymFBR40lY1ZX6vLH6KDX0a9mI9eOuOJY4bjp2UBubG4=";
};
cargoHash = "sha256-B10p57SZSzccs53/OtqFuftHJSxaHRpa+cHODqBo8t4=";
nativeBuildInputs = [ installShellFiles mdbook ];
buildInputs = lib.optionals stdenv.isDarwin [ libiconv ];
preCheck = ''
# USER must not be empty
export USER=just-user
export USERNAME=just-user
export JUST_CHOOSER="${coreutils}/bin/cat"
# Prevent string.rs from being changed
cp tests/string.rs $TMPDIR/string.rs
sed -i src/justfile.rs \
-i tests/*.rs \
-e "s@/bin/echo@${coreutils}/bin/echo@g" \
-e "s@/usr/bin/env@${coreutils}/bin/env@g"
# Return unchanged string.rs
cp $TMPDIR/string.rs tests/string.rs
'';
postBuild = ''
cargo run --package generate-book
# No linkcheck in sandbox
echo 'optional = true' >> book/en/book.toml
mdbook build book/en
find .
'';
checkFlags = [
"--skip=edit" # trying to run "vim" fails as there's no /usr/bin/env or which in the sandbox to find vim and the dependency is not easily patched
"--skip=run_shebang" # test case very rarely fails with "Text file busy"
"--skip=invoke_error_function" # wants JUST_CHOOSER to be fzf
"--skip=choose::default" # symlinks cat->fzf which fails as coreutils doesn't understand name
];
postInstall = ''
mkdir -p $doc/share/doc/$name
mv ./book/en/build/html $doc/share/doc/$name
installManPage man/just.1
installShellCompletion --cmd just \
--bash completions/just.bash \
--fish completions/just.fish \
--zsh completions/just.zsh
'';
setupHook = ./setup-hook.sh;
passthru.updateScript = nix-update-script { };
meta = with lib; {
homepage = "https://github.com/casey/just";
changelog = "https://github.com/casey/just/blob/${version}/CHANGELOG.md";
description = "A handy way to save and run project-specific commands";
license = licenses.cc0;
maintainers = with maintainers; [ xrelkd jk adamcstephens ];
mainProgram = "just";
};
}
|