blob: 285d181fe0957ffb9bd6502193ab3b26e0918c40 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
{ lib, stdenv, fetchurl, jre, makeWrapper }:
stdenv.mkDerivation rec {
pname = "google-java-format";
version = "1.17.0";
src = fetchurl {
url = "https://github.com/google/google-java-format/releases/download/v${version}/google-java-format-${version}-all-deps.jar";
sha256 = "sha256-MwaLu9zhCZmC7BFx9eICiY6zXykZz0hhQeQ5/G46QgM=";
};
dontUnpack = true;
nativeBuildInputs = [ makeWrapper ];
buildInputs = [ jre ];
installPhase = ''
runHook preInstall
mkdir -p $out/{bin,share/${pname}}
install -D ${src} $out/share/${pname}/google-java-format-${version}-all-deps.jar
makeWrapper ${jre}/bin/java $out/bin/${pname} \
--argv0 ${pname} \
--add-flags "--add-exports jdk.compiler/com.sun.tools.javac.api=ALL-UNNAMED" \
--add-flags "--add-exports jdk.compiler/com.sun.tools.javac.file=ALL-UNNAMED" \
--add-flags "--add-exports jdk.compiler/com.sun.tools.javac.parser=ALL-UNNAMED" \
--add-flags "--add-exports jdk.compiler/com.sun.tools.javac.tree=ALL-UNNAMED" \
--add-flags "--add-exports jdk.compiler/com.sun.tools.javac.util=ALL-UNNAMED" \
--add-flags "-jar $out/share/${pname}/google-java-format-${version}-all-deps.jar"
runHook postInstall
'';
meta = with lib; {
description = "Java source formatter by Google";
longDescription = ''
A program that reformats Java source code to comply with Google Java Style.
'';
homepage = "https://github.com/google/google-java-format";
sourceProvenance = with sourceTypes; [ binaryBytecode ];
license = licenses.asl20;
maintainers = [ maintainers.emptyflask ];
platforms = platforms.all;
mainProgram = "google-java-format";
};
}
|