blob: 5e07beaff6f7d3d446ee15dff038ac7909752f02 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
{ lib
, maven
, jre
, makeWrapper
, git
, fetchFromGitHub
, graphviz
, ensureNewerSourcesHook
}:
maven.buildMavenPackage rec {
pname = "schemaspy";
version = "6.1.1-SNAPSHOT";
src = fetchFromGitHub {
owner = "schemaspy";
repo = "schemaspy";
rev = "110b1614f9ae4aec0e4dc4e8f0e7c647274d3af6";
hash = "sha256-X5B34zGhD/NxcK8TQvwdk1NljGJ1HwfBp47ocbE4HiU=";
};
mvnParameters = "-Dmaven.test.skip=true";
mvnFetchExtraArgs = {
nativeBuildInputs = [
# the build system gets angry if it doesn't see git (even though it's not
# actually in a git repository)
git
maven
];
};
mvnHash = "sha256-1x6cNt6t3FnjRNg8iNYflkyDnuPFXGKoxhVJWoz2jIU=";
nativeBuildInputs = [
makeWrapper
git
# springframework boot gets angry about 1970 sources
# fix from https://github.com/nix-community/mavenix/issues/25
(ensureNewerSourcesHook { year = "1980"; })
];
wrappedPath = lib.makeBinPath [
graphviz
];
preBuild = ''
VERSION=${version}
SEMVER_STR=${version}
'';
installPhase = ''
install -D target/${pname}-${version}.jar $out/share/java/${pname}-${version}.jar
makeWrapper ${jre}/bin/java $out/bin/schemaspy \
--add-flags "-jar $out/share/java/${pname}-${version}.jar" \
--prefix PATH : "$wrappedPath"
'';
meta = with lib; {
homepage = "https://schemaspy.org";
description = "Document your database simply and easily";
mainProgram = "schemaspy";
license = licenses.lgpl3Plus;
maintainers = with maintainers; [ jraygauthier ];
};
}
|