blob: 71dfe3ef51aa09f28b4c3ca147458533c959b7a4 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
{ python3
, fetchPypi
, recurseIntoAttrs
, callPackage
}:
let
python = python3.override {
packageOverrides = self: super: {
sqlalchemy = super.sqlalchemy.overridePythonAttrs (oldAttrs: rec {
version = "1.4.49";
src = fetchPypi {
pname = "SQLAlchemy";
inherit version;
hash = "sha256-Bv8ly64ww5bEt3N0ZPKn/Deme32kCZk7GCsCTOyArtk=";
};
disabledTestPaths = [
"test/aaa_profiling"
"test/ext/mypy"
];
});
moto = super.moto.overridePythonAttrs (oldAttrs: rec {
# a lot of tests -> very slow, we already build them when building python packages
doCheck = false;
});
};
};
buildbot-pkg = python.pkgs.callPackage ./pkg.nix {
inherit buildbot;
};
buildbot-worker = python3.pkgs.callPackage ./worker.nix {
inherit buildbot;
};
buildbot = python.pkgs.callPackage ./master.nix {
inherit buildbot-pkg buildbot-worker buildbot-plugins;
};
buildbot-plugins = recurseIntoAttrs (callPackage ./plugins.nix {
inherit buildbot-pkg;
});
in
{
inherit buildbot buildbot-plugins buildbot-worker;
buildbot-ui = buildbot.withPlugins (with buildbot-plugins; [ www ]);
buildbot-full = buildbot.withPlugins (with buildbot-plugins; [
www console-view waterfall-view grid-view wsgi-dashboards badges
]);
}
|