blob: d7aec3527b3b5a62607b30d95396cbbd59dbd48b (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
|
{ lib, python3, git, pkgconfig }:
# Note:
# Conan has specific dependency demands; check
# https://github.com/conan-io/conan/blob/master/conans/requirements.txt
# https://github.com/conan-io/conan/blob/master/conans/requirements_server.txt
# on the release branch/commit we're packaging.
#
# Two approaches are used here to deal with that:
# Pinning the specific versions it wants in `newPython`,
# and using `substituteInPlace conans/requirements.txt ...`
# in `postPatch` to allow newer versions when we know
# (e.g. from changelogs) that they are compatible.
let newPython = python3.override {
packageOverrides = self: super: {
distro = super.distro.overridePythonAttrs (oldAttrs: rec {
version = "1.1.0";
src = oldAttrs.src.override {
inherit version;
sha256 = "1vn1db2akw98ybnpns92qi11v94hydwp130s8753k6ikby95883j";
};
});
node-semver = super.node-semver.overridePythonAttrs (oldAttrs: rec {
version = "0.6.1";
src = oldAttrs.src.override {
inherit version;
sha256 = "1dv6mjsm67l1razcgmq66riqmsb36wns17mnipqr610v0z0zf5j0";
};
});
pluginbase = super.pluginbase.overridePythonAttrs (oldAttrs: rec {
version = "0.7";
src = oldAttrs.src.override {
inherit version;
sha256 = "c0abe3218b86533cca287e7057a37481883c07acef7814b70583406938214cc8";
};
});
};
};
in newPython.pkgs.buildPythonApplication rec {
version = "1.25.0";
pname = "conan";
src = newPython.pkgs.fetchPypi {
inherit pname version;
sha256 = "1wgmx6s4h5m6zixb3wlaicy56rsqcy2srzmvii80xdx9g5wvi9pv";
};
propagatedBuildInputs = with newPython.pkgs; [
bottle
colorama
dateutil
deprecation
distro
fasteners
future
jinja2
node-semver
patch-ng
pluginbase
pygments
pyjwt
pylint # Not in `requirements.txt` but used in hooks, see https://github.com/conan-io/conan/pull/6152
pyyaml
requests
six
tqdm
urllib3
];
checkInputs = [
pkgconfig
git
] ++ (with newPython.pkgs; [
codecov
mock
pytest
node-semver
nose
parameterized
webtest
]);
# Conan 1.14.0 has removed all tests from the Pypi source dist:
# https://github.com/conan-io/conan/pull/4713
# We have recommended they be added back:
# https://github.com/conan-io/conan/issues/4563#issuecomment-602225083
doCheck = false;
postPatch = ''
substituteInPlace conans/requirements.txt \
--replace "PyYAML>=3.11, <3.14.0" "PyYAML" \
--replace "deprecation>=2.0, <2.1" "deprecation"
'';
meta = with lib; {
homepage = "https://conan.io";
description = "Decentralized and portable C/C++ package manager";
license = licenses.mit;
maintainers = with maintainers; [ HaoZeke ];
platforms = platforms.linux;
};
}
|