blob: b3dc5a236ea46869e3411498b56e947acb3d1c36 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
{ lib, buildPythonPackage, pythonOlder, fetchFromGitHub, certifi, numpy, sgp4, jplephem
, pandas, ipython, matplotlib, assay
}:
buildPythonPackage rec {
pname = "skyfield";
version = "1.45";
format = "setuptools";
src = fetchFromGitHub {
owner = "skyfielders";
repo = "python-skyfield";
rev = version;
hash = "sha256-kZrXNVE+JGPGiVsd6CTwOqfciYLsD2A4pTS3FpqO+Dk=";
};
# Fix broken tests on "exotic" platforms.
# https://github.com/skyfielders/python-skyfield/issues/582#issuecomment-822033858
postPatch = ''
substituteInPlace skyfield/tests/test_planetarylib.py \
--replace "if IS_32_BIT" "if True"
'';
propagatedBuildInputs = [ certifi numpy sgp4 jplephem ];
nativeCheckInputs = [ pandas ipython matplotlib assay ];
# assay is broken on Python >= 3.11
# https://github.com/brandon-rhodes/assay/issues/15
doCheck = pythonOlder "3.11";
checkPhase = ''
runHook preCheck
cd ci
assay --batch skyfield.tests
runHook postCheck
'';
pythonImportsCheck = [ "skyfield" ];
meta = with lib; {
homepage = "https://github.com/skyfielders/python-skyfield";
description = "Elegant astronomy for Python";
license = licenses.mit;
maintainers = with maintainers; [ zane ];
};
}
|