1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
|
{ lib
, stdenv
, buildPythonPackage
, pythonOlder
, pythonAtLeast
, fetchFromGitHub
, substituteAll
, gdb
, django
, flask
, gevent
, psutil
, pytest-timeout
, pytest-xdist
, pytestCheckHook
, requests
, llvmPackages
}:
buildPythonPackage rec {
pname = "debugpy";
version = "1.6.7";
format = "setuptools";
# Currently doesn't support 3.11:
# https://github.com/microsoft/debugpy/issues/1107
disabled = pythonOlder "3.7" || pythonAtLeast "3.11";
src = fetchFromGitHub {
owner = "microsoft";
repo = "debugpy";
rev = "refs/tags/v${version}";
hash = "sha256-porQTFvcLaIkvhWPM4vWR0ohlcFRkRwSLpQJNg25Tj4=";
};
patches = [
# Use nixpkgs version instead of versioneer
(substituteAll {
src = ./hardcode-version.patch;
inherit version;
})
# Fix importing debugpy in:
# - test_nodebug[module-launch(externalTerminal)]
# - test_nodebug[module-launch(integratedTerminal)]
#
# NOTE: The import failures seen in these tests without the patch
# will be seen if a user "installs" debugpy by adding it to PYTHONPATH.
# To avoid this issue, debugpy should be installed using python.withPackages:
# python.withPackages (ps: with ps; [ debugpy ])
./fix-test-pythonpath.patch
] ++ lib.optionals stdenv.isLinux [
# Hard code GDB path (used to attach to process)
(substituteAll {
src = ./hardcode-gdb.patch;
inherit gdb;
})
] ++ lib.optionals stdenv.isDarwin [
# Hard code LLDB path (used to attach to process)
(substituteAll {
src = ./hardcode-lldb.patch;
inherit (llvmPackages) lldb;
})
];
# Remove pre-compiled "attach" libraries and recompile for host platform
# Compile flags taken from linux_and_mac/compile_linux.sh & linux_and_mac/compile_mac.sh
preBuild = ''(
set -x
cd src/debugpy/_vendored/pydevd/pydevd_attach_to_process
rm *.so *.dylib *.dll *.exe *.pdb
${stdenv.cc}/bin/c++ linux_and_mac/attach.cpp -Ilinux_and_mac -fPIC -nostartfiles ${{
"x86_64-linux" = "-shared -o attach_linux_amd64.so";
"i686-linux" = "-shared -o attach_linux_x86.so";
"aarch64-linux" = "-shared -o attach_linux_arm64.so";
"x86_64-darwin" = "-std=c++11 -lc -D_REENTRANT -dynamiclib -o attach_x86_64.dylib";
"i686-darwin" = "-std=c++11 -lc -D_REENTRANT -dynamiclib -o attach_x86.dylib";
"aarch64-darwin" = "-std=c++11 -lc -D_REENTRANT -dynamiclib -o attach_arm64.dylib";
}.${stdenv.hostPlatform.system} or (throw "Unsupported system: ${stdenv.hostPlatform.system}")}
)'';
nativeCheckInputs = [
django
flask
gevent
psutil
pytest-timeout
pytest-xdist
pytestCheckHook
requests
];
preCheck = ''
# Scale default timeouts by a factor of 4 to avoid flaky builds
# https://github.com/microsoft/debugpy/pull/1286 if merged would
# allow us to disable the timeouts altogether
export DEBUGPY_PROCESS_SPAWN_TIMEOUT=60
export DEBUGPY_PROCESS_EXIT_TIMEOUT=20
'' + lib.optionalString (stdenv.isDarwin && stdenv.isAarch64) ''
# https://github.com/python/cpython/issues/74570#issuecomment-1093748531
export no_proxy='*';
'';
postCheck = lib.optionalString (stdenv.isDarwin && stdenv.isAarch64) ''
unset no_proxy
'';
# Override default arguments in pytest.ini
pytestFlagsArray = [
"--timeout=0"
];
# Fixes hanging tests on Darwin
__darwinAllowLocalNetworking = true;
disabledTests = [
# https://github.com/microsoft/debugpy/issues/1241
"test_flask_breakpoint_multiproc"
];
pythonImportsCheck = [
"debugpy"
];
meta = with lib; {
description = "An implementation of the Debug Adapter Protocol for Python";
homepage = "https://github.com/microsoft/debugpy";
changelog = "https://github.com/microsoft/debugpy/releases/tag/v${version}";
license = licenses.mit;
maintainers = with maintainers; [ kira-bruneau ];
platforms = [ "x86_64-linux" "i686-linux" "aarch64-linux" "x86_64-darwin" "i686-darwin" "aarch64-darwin" ];
};
}
|