nixpkgs/pkgs/development/python-modules/cxxfilt/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

{ lib
, stdenv
, buildPythonPackage
, fetchPypi
, gcc-unwrapped
}:
buildPythonPackage rec {
  pname = "cxxfilt";
  version = "0.2.2";

  src = fetchPypi {
    inherit pname version;
    sha256 = "ef6810e76d16c95c11b96371e2d8eefd1d270ec03f9bcd07590e8dcc2c69e92b";
  };

  postPatch = let
    libstdcpp = "${lib.getLib gcc-unwrapped}/lib/libstdc++${stdenv.hostPlatform.extensions.sharedLibrary}";
  in ''
    substituteInPlace cxxfilt/__init__.py \
      --replace "find_any_library('stdc++', 'c++')" '"${libstdcpp}"'
  '';

  # no tests
  doCheck = false;

  pythonImportsCheck = [
    "cxxfilt"
  ];

  meta = with lib; {
    description = "Demangling C++ symbols in Python / interface to abi::__cxa_demangle ";
    homepage = "https://github.com/afq984/python-cxxfilt";
    license = licenses.bsd2;
    maintainers = teams.determinatesystems.members;
  };
}