blob: ae920f4cb0d23d065ef558cf9c5e5d62b8e3609a (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
|
{ stdenv, lib, fetchFromGitHub, cmake, fetchpatch
}:
stdenv.mkDerivation rec {
pname = "reproc";
version = "14.2.4";
src = fetchFromGitHub {
owner = "DaanDeMeyer";
repo = "reproc";
rev = "v${version}";
sha256 = "sha256-LWzBeKhE7cSiZsK8xWzoTdrOcPiU/zEkmi40WiFytic=";
};
patches = [
(fetchpatch{
name = "reproc-gcc-13-2.patch";
url = "https://github.com/DaanDeMeyer/reproc/commit/0b23d88894ccedde04537fa23ea55cb2f8365342.patch";
sha256 = "sha256-QyC0UcKAWCKSvSvyZTLI2eF/TuuqbGGH6cOQrS2DiCE=";
})
(fetchpatch{
name = "reproc-gcc-13-1.patch";
url = "https://github.com/DaanDeMeyer/reproc/commit/9f399675b821e175f85ac3ee6e3fd2e6056573eb.patch";
sha256 = "sha256-h/gnDFPWPpUFkys10YXjjEPibgRT1atHSVwbO0kId+U=";
})
];
nativeBuildInputs = [ cmake ];
cmakeFlags = [
"-DCMAKE_INSTALL_LIBDIR=lib"
"-DBUILD_SHARED_LIBS=ON"
"-DREPROC++=ON"
"-DREPROC_TEST=ON"
];
# https://github.com/DaanDeMeyer/reproc/issues/81
postPatch = ''
substituteInPlace reproc++/reproc++.pc.in \
--replace '$'{exec_prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
--replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@
substituteInPlace reproc/reproc.pc.in \
--replace '$'{exec_prefix}/@CMAKE_INSTALL_LIBDIR@ @CMAKE_INSTALL_FULL_LIBDIR@ \
--replace '$'{prefix}/@CMAKE_INSTALL_INCLUDEDIR@ @CMAKE_INSTALL_FULL_INCLUDEDIR@
'';
meta = with lib; {
homepage = "https://github.com/DaanDeMeyer/reproc";
description = "A cross-platform (C99/C++11) process library";
license = licenses.mit;
platforms = platforms.all;
};
}
|