1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
|
{ lib
, stdenv
, callPackage
, fetchFromGitHub
, fetchpatch
, testers
, enableE57 ? lib.meta.availableOn stdenv.hostPlatform libe57format
, cmake
, curl
, gdal
, hdf5-cpp
, LASzip
, libe57format
, libgeotiff
, libtiff
, libxml2
, openscenegraph
, pkg-config
, postgresql
, proj
, tiledb
, xercesc
, zlib
, zstd
}:
stdenv.mkDerivation (finalAttrs: {
pname = "pdal";
version = "2.6.3";
src = fetchFromGitHub {
owner = "PDAL";
repo = "PDAL";
rev = finalAttrs.version;
sha256 = "sha256-wrgEbCYOGW1yrVxyX+UDa5jcUqab3letEGuvWnYvtac=";
};
patches = [
# Fix running tests
# https://github.com/PDAL/PDAL/issues/4280
(fetchpatch {
url = "https://patch-diff.githubusercontent.com/raw/PDAL/PDAL/pull/4291.patch";
sha256 = "sha256-jFS+trwMRBfm+MpT0CcuD/hdYmfyuQj2zyoe06B6G9U=";
})
];
nativeBuildInputs = [
cmake
pkg-config
];
buildInputs = [
curl
gdal
hdf5-cpp
LASzip
libgeotiff
libtiff
libxml2
openscenegraph
postgresql
proj
tiledb
xercesc
zlib
zstd
] ++ lib.optionals enableE57 [
libe57format
];
cmakeFlags = [
"-DBUILD_PLUGIN_E57=${if enableE57 then "ON" else "OFF"}"
"-DBUILD_PLUGIN_HDF=ON"
"-DBUILD_PLUGIN_PGPOINTCLOUD=ON"
"-DBUILD_PLUGIN_TILEDB=ON"
"-DWITH_COMPLETION=ON"
"-DWITH_TESTS=ON"
"-DBUILD_PGPOINTCLOUD_TESTS=OFF"
# Plugins can probably not be made work easily:
"-DBUILD_PLUGIN_CPD=OFF"
"-DBUILD_PLUGIN_FBX=OFF" # Autodesk FBX SDK is gratis+proprietary; not packaged in nixpkgs
"-DBUILD_PLUGIN_GEOWAVE=OFF"
"-DBUILD_PLUGIN_I3S=OFF"
"-DBUILD_PLUGIN_ICEBRIDGE=OFF"
"-DBUILD_PLUGIN_MATLAB=OFF"
"-DBUILD_PLUGIN_MBIO=OFF"
"-DBUILD_PLUGIN_MRSID=OFF"
"-DBUILD_PLUGIN_NITF=OFF"
"-DBUILD_PLUGIN_OCI=OFF"
"-DBUILD_PLUGIN_RDBLIB=OFF" # Riegl rdblib is proprietary; not packaged in nixpkgs
"-DBUILD_PLUGIN_RIVLIB=OFF"
];
doCheck = true;
disabledTests = [
# Tests failing due to TileDB library implementation, disabled also
# by upstream CI.
# See: https://github.com/PDAL/PDAL/blob/bc46bc77f595add4a6d568a1ff923d7fe20f7e74/.github/workflows/linux.yml#L81
"pdal_io_tiledb_writer_test"
"pdal_io_tiledb_reader_test"
"pdal_io_tiledb_time_writer_test"
"pdal_io_tiledb_time_reader_test"
"pdal_io_tiledb_bit_fields_test"
"pdal_io_tiledb_utils_test"
"pdal_io_e57_read_test"
"pdal_io_e57_write_test"
"pdal_io_stac_reader_test"
# Segfault
"pdal_io_hdf_reader_test"
# Failure
"pdal_app_plugin_test"
];
checkPhase = ''
runHook preCheck
# tests are flaky and they seem to fail less often when they don't run in
# parallel
ctest -j 1 --output-on-failure -E '^${lib.concatStringsSep "|" finalAttrs.disabledTests}$'
runHook postCheck
'';
passthru.tests = {
version = testers.testVersion {
package = finalAttrs.finalPackage;
command = "pdal --version";
version = "pdal ${finalAttrs.finalPackage.version}";
};
pdal = callPackage ./tests.nix { pdal = finalAttrs.finalPackage; };
pkg-config = testers.testMetaPkgConfig finalAttrs.finalPackage;
};
meta = with lib; {
description = "PDAL is Point Data Abstraction Library. GDAL for point cloud data";
homepage = "https://pdal.io";
license = licenses.bsd3;
maintainers = teams.geospatial.members;
platforms = platforms.all;
pkgConfigModules = [ "pdal" ];
};
})
|