blob: 7625db9a59533d5210d73a3ad5c18c295cca53c6 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
{lib, stdenv, fetchurl, libGLU, libGL, freeglut, glew, libXmu, libXext, libX11
, qmake, GLUT, fixDarwinDylibNames }:
stdenv.mkDerivation rec {
version = "1.4.2";
pname = "opencsg";
src = fetchurl {
url = "http://www.opencsg.org/OpenCSG-${version}.tar.gz";
sha256 = "1ysazynm759gnw1rdhn9xw9nixnzrlzrc462340a6iif79fyqlnr";
};
nativeBuildInputs = [ qmake ]
++ lib.optional stdenv.isDarwin fixDarwinDylibNames;
buildInputs = [ glew ]
++ lib.optionals stdenv.isLinux [ libGLU libGL freeglut libXmu libXext libX11 ]
++ lib.optional stdenv.isDarwin GLUT;
doCheck = false;
patches = [ ./fix-pro-files.patch ];
preConfigure = ''
rm example/Makefile src/Makefile
qmakeFlags=("''${qmakeFlags[@]}" "INSTALLDIR=$out")
'';
postInstall = ''
install -D license.txt "$out/share/doc/opencsg/license.txt"
'' + lib.optionalString stdenv.isDarwin ''
mkdir -p $out/Applications
mv $out/bin/*.app $out/Applications
rmdir $out/bin || true
'';
dontWrapQtApps = true;
postFixup = lib.optionalString stdenv.isDarwin ''
app=$out/Applications/opencsgexample.app/Contents/MacOS/opencsgexample
install_name_tool -change \
$(otool -L $app | awk '/opencsg.+dylib/ { print $1 }') \
$(otool -D $out/lib/libopencsg.dylib | tail -n 1) \
$app
'';
meta = with lib; {
description = "Constructive Solid Geometry library";
homepage = "http://www.opencsg.org/";
platforms = platforms.unix;
maintainers = [ maintainers.raskin ];
license = licenses.gpl2;
};
}
|