path: root/nixpkgs/pkgs/development/libraries/mesa/default.nix

{ stdenv, fetchurl, fetchpatch, lib
, pkgconfig, autoreconfHook
, expat, zlib, xorg, wayland, wayland-protocols
, python2, python2Packages
, enableRadv ? stdenv.isLinux
, galliumDrivers ? null
, driDrivers ? null
, vulkanDrivers ? null
, eglPlatforms ? [ "x11" ] ++ lib.optionals stdenv.isLinux [ "wayland" "drm" ]

, xvmcSupport ? true
, vdpauSupport ? true, libvdpau
, omxBellagioSupport ? stdenv.isLinux, libomxil-bellagio
, vaSupport ? stdenv.isLinux, libva-minimal
, libdrmSupport ? stdenv.isLinux, libdrm
, libelfSupport ? stdenv.isLinux, libelf
, llvmSupport ? true, llvmPackages
, libglvndSupport ? true, libglvnd
, valgrindSupport ? stdenv.isLinux, valgrind-light

, OpenGL, Xplugin
}:

with lib;

assert elem "drm" eglPlatforms -> libdrmSupport;
assert elem "wayland" eglPlatforms -> libdrmSupport;
assert xvmcSupport -> elem "x11" eglPlatforms;
assert vdpauSupport -> elem "x11" eglPlatforms;
assert enableRadv -> libdrmSupport && llvmSupport && libelfSupport;

/** Packaging design:
  - The basic mesa ($out) contains headers and libraries (GLU is in libGLU now).
    This or the mesa attribute (which also contains GLU) are small (~ 2 MB, mostly headers)
    and are designed to be the buildInput of other packages.
  - DRI drivers are compiled into $drivers output, which is much bigger and
    depends on LLVM. These should be searched at runtime in
    "/run/opengl-driver{,-32}/lib/*" and so are kind-of impure (given by NixOS).
    (I suppose on non-NixOS one would create the appropriate symlinks from there.)
  - libOSMesa is in $osmesa (~4 MB)
*/

if ! elem stdenv.hostPlatform.system platforms.mesaPlatforms then
  throw "unsupported platform for Mesa"
else

let
  defaultGalliumDrivers =
    optionals (elem "drm" eglPlatforms)
      ([ "virgl" "nouveau" ]
        ++ (if stdenv.isAarch32 then ["freedreno" "vc4" "etnaviv" "imx"]
          else if stdenv.isAarch64 then [ "vc4" ]
          else
            ([ "svga" "i915" ]
              ++ optionals llvmSupport ([ "r300" ])
                ++ optionals libelfSupport [ "r600" "radeonsi" ])));

  defaultDriDrivers =
    optionals (elem "drm" eglPlatforms)
      ([ "nouveau" ] ++
        optionals (stdenv.isAarch32 || stdenv.isAarch64)
          [ "i915" "i965" "radeon" "r200" ]);

  defaultVulkanDrivers =
    optional enableRadv "radeon"
    ++ (optional (stdenv.isLinux
                  && libdrmSupport
                  && !stdenv.isAarch32
                  && !stdenv.isAarch64) "intel");
in

let gallium_ = galliumDrivers; dri_ = driDrivers; vulkan_ = vulkanDrivers; in

let
  galliumDrivers =
    (if gallium_ == null
          then defaultGalliumDrivers
          else gallium_)
    ++ lib.optional stdenv.isLinux "swrast";
  driDrivers =
    (if dri_ == null
      then optionals (elem "drm" eglPlatforms) defaultDriDrivers
      else dri_) ++ lib.optional stdenv.isLinux "swrast";
  vulkanDrivers =
    if vulkan_ == null
    then defaultVulkanDrivers
    else vulkan_;
in

assert xvmcSupport ->
  elem "r600" galliumDrivers || elem "nouveau" galliumDrivers;
assert omxBellagioSupport ->
  intersectLists galliumDrivers [ "r600" "radeonsi" "nouveau" ] != [];
assert vaSupport ->
  intersectLists galliumDrivers [ "r600" "radeonsi" "nouveau" ] != [];
assert vdpauSupport ->
  intersectLists galliumDrivers [ "r300" "r600" "radeonsi" "nouveau" ] != [];

let
  version = "18.3.4";
  branch  = head (splitString "." version);
in

let self = stdenv.mkDerivation {
  name = "mesa-noglu-${version}";

  src =  fetchurl {
    urls = [
      "ftp://ftp.freedesktop.org/pub/mesa/mesa-${version}.tar.xz"
      "ftp://ftp.freedesktop.org/pub/mesa/${version}/mesa-${version}.tar.xz"
      "ftp://ftp.freedesktop.org/pub/mesa/older-versions/${branch}.x/${version}/mesa-${version}.tar.xz"
      "https://mesa.freedesktop.org/archive/mesa-${version}.tar.xz"
    ];
    sha256 = "01xv03ah4l5lcfx015n3fg1620dh4nbbv6gmhh6zhdsx6sj4sc9j";
  };

  prePatch = "patchShebangs .";

  # TODO:
  #  revive ./dricore-gallium.patch when it gets ported (from Ubuntu), as it saved
  #  ~35 MB in $drivers; watch https://launchpad.net/ubuntu/+source/mesa/+changelog
  patches = [
    ./symlink-drivers.patch
    ./missing-includes.patch # dev_t needs sys/stat.h, time_t needs time.h, etc.-- fixes build w/musl
    ./disk_cache-include-dri-driver-path-in-cache-key.patch

    (fetchpatch {
      url = https://cgit.freedesktop.org/mesa/mesa/patch/?id=eb44c36cf1729e7e200b77cf8ea755dff72d1639;
      sha256 = "1izp38yja917241y7qslbkbmxv5ll9746ivgg2q5s64cwiydwrcc";
    })
    (fetchpatch {
      url = https://cgit.freedesktop.org/mesa/mesa/patch/?id=bcc4bfc8e80da5dc4c6ee44f791f2112dac208d1;
      sha256 = "0rijkx80anbb7g14cg9g11ha7lcf7sixc7xsjam6myyd68nl3n5n";
    })
  ] ++ lib.optional stdenv.isDarwin ./darwin-clock-gettime.patch;

  outputs = [ "out" "dev" "drivers" ]
            ++ lib.optional (elem "swrast" galliumDrivers) "osmesa";

  # TODO: Figure out how to enable opencl without having a runtime dependency on clang
  configureFlags = [
    "--sysconfdir=${libglvnd.driverLink}/etc"
    "--localstatedir=/var"
    "--with-dri-driverdir=$(drivers)/lib/dri"
    "--with-dri-searchpath=${libglvnd.driverLink}/lib/dri"
    "--with-va-libdir=$(drivers)/lib/dri"
    "--with-platforms=${concatStringsSep "," eglPlatforms}"
    "--with-gallium-drivers=${concatStringsSep "," galliumDrivers}"
    "--with-dri-drivers=${concatStringsSep "," driDrivers}"
    "--with-vulkan-drivers=${concatStringsSep "," vulkanDrivers}"
    "--enable-texture-float"

    # XXX: I'm not sure whether x11 is actually required in theory for
    #      dri3, but attempting to build with dri3 and without x11
    #      results in a compile error. For future versions, check
    #      whether this is still the case and remove the check if not:
    #
    #      Last checked: v18.3.4
    (enableFeature (stdenv.isLinux && elem "x11" eglPlatforms && libdrmSupport) "dri3")

    # Direct3D in Wine
    (enableFeature (any (d: d != "swrast") galliumDrivers) "nine")

    (enableFeature libglvndSupport "libglvnd")
    "--enable-dri"
    "--enable-driglx-direct"
    "--enable-gles1"
    "--enable-gles2"
    (enableFeature (elem "x11" eglPlatforms && libdrmSupport) "glx")
    # https://bugs.freedesktop.org/show_bug.cgi?id=35268
    (enableFeature (!stdenv.hostPlatform.isMusl) "glx-tls")
    # used by wine
    (enableFeature (elem "swrast" galliumDrivers) "gallium-osmesa")
    (enableFeature llvmSupport "llvm")
    (enableFeature stdenv.isLinux "egl")

    # used in vmware driver
    (enableFeature (any (d: d != "swrast") galliumDrivers) "xa")

    (enableFeature libdrmSupport "gbm")
    (enableFeature xvmcSupport "xvmc")
    (enableFeature vdpauSupport "vdpau")
    "--enable-shared-glapi"
    "--enable-llvm-shared-libs"
    (enableFeature omxBellagioSupport "omx-bellagio")
    (enableFeature vaSupport "va")
    "--disable-opencl"

    "--with-d3d-libdir=$(drivers)/lib"
    "--with-xvmc-libdir=$(drivers)/lib"
    "--with-vdpau-libdir=$(drivers)/lib"
    "--with-omx-bellagio-libdir=$(drivers)/lib"
  ];

  nativeBuildInputs = [ autoreconfHook pkgconfig python2 ]
    ++ optionals enableRadv [ python2Packages.Mako ];

  propagatedBuildInputs =
    optionals (elem "x11" eglPlatforms) (with xorg; [ libXdamage libXxf86vm ])
    ++ optional libdrmSupport libdrm
    ++ optionals stdenv.isDarwin [ OpenGL Xplugin ];

  buildInputs = [ expat zlib ]
    ++ optional libglvndSupport libglvnd
    ++ optional llvmSupport llvmPackages.llvm
    ++ optional libelfSupport libelf
    ++ optionals (elem "wayland" eglPlatforms) [ wayland wayland-protocols ]
    ++ optional xvmcSupport xorg.libXvMC
    ++ optional vdpauSupport libvdpau
    ++ optional vaSupport libva-minimal
    ++ optional omxBellagioSupport libomxil-bellagio
    ++ optional valgrindSupport valgrind-light

    ++ optionals (elem "x11" eglPlatforms)
      (with xorg; [
        xorgproto
        libX11 libXext libxcb libxshmfence libXrandr
      ]);

  enableParallelBuilding = true;
  doCheck = false;

  installFlags = [
    "sysconfdir=\${drivers}/etc"
    "localstatedir=\${TMPDIR}"
    "vendorjsondir=\${out}/share/glvnd/egl_vendor.d"
  ];

  # TODO: probably not all .la files are completely fixed, but it shouldn't matter;
  postInstall = ''
    # Some installs don't have any drivers so this directory is never created.
    mkdir -p $drivers
  '' + optionalString (galliumDrivers != []) ''
    # move libOSMesa to $osmesa, as it's relatively big
    mkdir -p {$osmesa,$drivers}/lib/
    mv -t $osmesa/lib/ $out/lib/libOSMesa*

    # now fix references in .la files
    sed "/^libdir=/s,$out,$osmesa," -i $osmesa/lib/libOSMesa*.la

    # set the default search path for DRI drivers; used e.g. by X server
    substituteInPlace "$dev/lib/pkgconfig/dri.pc" --replace '$(drivers)' "${libglvnd.driverLink}"

    # remove GLES libraries; they are provided by libglvnd
    rm $out/lib/lib{GLESv1_CM,GLESv2}.*

    # remove pkgconfig files for GL/GLES/EGL; they are provided by libGL.
    rm -f $dev/lib/pkgconfig/{gl,egl,glesv1_cm,glesv2}.pc

    # move vendor files
    mv $out/share/ $drivers/

    # Update search path used by glvnd
    for js in $drivers/share/glvnd/egl_vendor.d/*.json; do
      substituteInPlace "$js" --replace '"libEGL_' '"'"$drivers/lib/libEGL_"
    done

    # Update search path used by pkg-config
    substituteInPlace $dev/lib/pkgconfig/dri.pc --replace $out $drivers
  '' + optionalString (vulkanDrivers != []) ''
    # Update search path used by Vulkan (it's pointing to $out but
    # drivers are in $drivers)
    for js in $drivers/share/vulkan/icd.d/*.json; do
      substituteInPlace "$js" --replace "$out" "$drivers"
    done
  '' + optionalString (any (d: d != "swrast") galliumDrivers) ''
    # Update search path used by pkg-config
    for pc in $dev/lib/pkgconfig/{d3d,xatracker}.pc; do
      substituteInPlace "$pc" --replace $out $drivers
    done
    # move gallium-related stuff to $drivers, so $out doesn't depend on LLVM
    mv $out/lib/libxatracker* $drivers/lib
  '' + optionalString (vulkanDrivers != []) ''
    # move gallium-related stuff to $drivers, so $out doesn't depend on LLVM
    mv $out/lib/libvulkan_* $drivers/lib
  '' + optionalString libglvndSupport ''
    # Move other drivers to a separate output
    mv $out/lib/lib*_mesa* $drivers/lib
  '';

  # TODO:
  #  check $out doesn't depend on llvm: builder failures are ignored
  #  for some reason grep -qv '${llvmPackages.llvm}' -R "$out";
  postFixup = optionalString (galliumDrivers != []) ''
    # add RPATH so the drivers can find the moved libgallium and libdricore9
    # moved here to avoid problems with stripping patchelfed files
    for lib in $drivers/lib/*.so* $drivers/lib/*/*.so*; do
      if [[ ! -L "$lib" ]]; then
        patchelf --set-rpath "$(patchelf --print-rpath $lib):$drivers/lib" "$lib"
      fi
    done
  '';

  passthru = {
    inherit libdrm version;
    inherit (libglvnd) driverLink;

    stubs = stdenv.mkDerivation {
      name = "libGL-${libglvnd.version}";
      outputs = [ "out" "dev" ];

      # Use stub libraries from libglvnd and headers from Mesa.
      buildCommand = ''
        mkdir -p $out/nix-support
        ln -s ${libglvnd.out}/lib $out/lib

        mkdir -p $dev/{,lib/pkgconfig,nix-support}
        echo "$out" > $dev/nix-support/propagated-build-inputs
        ln -s ${self.dev}/include $dev/include

        genPkgConfig() {
          local name="$1"
          local lib="$2"

          cat <<EOF >$dev/lib/pkgconfig/$name.pc
        Name: $name
        Description: $lib library
        Version: ${self.version}
        Libs: -L${libglvnd.out}/lib -l$lib
        Cflags: -I${self.dev}/include
        EOF
        }

        genPkgConfig gl GL
        genPkgConfig egl EGL
        genPkgConfig glesv1_cm GLESv1_CM
        genPkgConfig glesv2 GLESv2
      '' + lib.optionalString stdenv.isDarwin ''
        echo ${OpenGL} > $out/nix-support/propagated-build-inputs
      '';
    };
  };

  meta = with stdenv.lib; {
    description = "An open source implementation of OpenGL";
    homepage = https://www.mesa3d.org/;
    license = licenses.mit; # X11 variant, in most files
    platforms = platforms.linux ++ platforms.darwin;
    maintainers = with maintainers; [ vcunat ];
  };
};
in self