1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
{ lib
, stdenv
, fetchFromGitHub
, intltool
, pkg-config
, doxygen
, autoreconfHook
, buildPackages
, curl
, gettext
, libiconv
, readline
, libxml2
, mpfr
, icu
, gnuplot
}:
stdenv.mkDerivation (finalAttrs: {
pname = "libqalculate";
version = "4.9.0";
src = fetchFromGitHub {
owner = "qalculate";
repo = "libqalculate";
rev = "v${finalAttrs.version}";
hash = "sha256-6W65dg2pZeio3ZVgVLQZrz/eReYcPiYf52zjcaRfE8E=";
};
outputs = [ "out" "dev" "doc" ];
nativeBuildInputs = [
intltool
pkg-config
autoreconfHook
doxygen
];
depsBuildBuild = [
buildPackages.stdenv.cc
];
buildInputs = [
curl
gettext
libiconv
readline
];
propagatedBuildInputs = [
libxml2
mpfr
icu
];
enableParallelBuilding = true;
preConfigure = ''
intltoolize -f
'';
patchPhase = ''
substituteInPlace libqalculate/Calculator-plot.cc \
--replace 'commandline = "gnuplot"' 'commandline = "${gnuplot}/bin/gnuplot"' \
--replace '"gnuplot - ' '"${gnuplot}/bin/gnuplot - '
'' + lib.optionalString stdenv.cc.isClang ''
substituteInPlace src/qalc.cc \
--replace 'printf(_("aborted"))' 'printf("%s", _("aborted"))'
'';
preBuild = ''
pushd docs/reference
doxygen Doxyfile
popd
'';
meta = with lib; {
description = "An advanced calculator library";
homepage = "http://qalculate.github.io";
license = licenses.gpl2Plus;
maintainers = with maintainers; [ gebner doronbehar alyaeanyx ];
mainProgram = "qalc";
platforms = platforms.all;
};
})
|