1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
{ lib
, stdenv
, fetchFromGitHub
, cmake
, imgui
, ninja
, withEmscripten ? false, emscripten
, withCurl ? (!withEmscripten), curl
, withNcurses ? (!withEmscripten), ncurses
, static ? withEmscripten
, darwin
}:
stdenv.mkDerivation rec {
pname = "imtui";
version = "1.0.5";
src = fetchFromGitHub {
owner = "ggerganov";
repo = pname;
rev = "v${version}";
hash = "sha256-eHQPDEfxKGLdiOi0lUUgqJcmme1XJLSPAafT223YK+U=";
};
nativeBuildInputs = [ cmake ninja ];
buildInputs = lib.optional withEmscripten emscripten
++ lib.optional withCurl curl
++ lib.optional withNcurses ncurses
++ lib.optional stdenv.isDarwin darwin.apple_sdk.frameworks.Cocoa;
postPatch = ''
cp -r ${imgui}/include/imgui third-party/imgui
'' + lib.optionalString (lib.versionAtLeast imgui.version "1.90.1") ''
substituteInPlace src/imtui-impl-{emscripten,ncurses}.cpp \
--replace "ImGuiKey_KeyPadEnter" "ImGuiKey_KeypadEnter"
'';
cmakeFlags = [
"-DEMSCRIPTEN:BOOL=${if withEmscripten then "ON" else "OFF"}"
"-DIMTUI_SUPPORT_CURL:BOOL=${if withCurl then "ON" else "OFF"}"
"-DIMTUI_SUPPORT_NCURSES:BOOL=${if withNcurses then "ON" else "OFF"}"
"-DBUILD_SHARED_LIBS:BOOL=${if (!static) then "ON" else "OFF"}"
"-DIMTUI_BUILD_EXAMPLES:BOOL=OFF"
"-DIMTUI_INSTALL_IMGUI_HEADERS:BOOL=OFF"
];
postInstall = ''
rm -rf $out/include/imgui
'';
meta = with lib; {
description = "Immediate mode text-based user interface library";
longDescription = ''
ImTui is an immediate mode text-based user interface library. Supports 256
ANSI colors and mouse/keyboard input.
'';
homepage = "https://imtui.ggerganov.com";
changelog = "https://github.com/ggerganov/imtui/blob/${src.rev}/CHANGELOG.md";
license = licenses.mit;
maintainers = with maintainers; [ azahi ];
platforms = platforms.unix;
};
}
|