nixpkgs/pkgs/development/libraries/febio/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

{ lib, stdenv, fetchFromGitHub, cmake, boost, eigen, libxml2, mpi, python3
, mklSupport ? true, mkl
}:

stdenv.mkDerivation rec {
  pname = "FEBio";
  version = "3.6";

  src = fetchFromGitHub {
    owner = "febiosoftware";
    repo = pname;
    rev = "v${version}";
    sha256 = "187s4lyzr806xla3smq3lsvj3f6wxlhfkban89w0fnyfmfb8w9am";
  };

  patches = [
    ./fix-cmake.patch  # cannot find mkl libraries without this
  ];

  cmakeFlags = lib.optional mklSupport "-DUSE_MKL=On"
    ++ lib.optional mklSupport "-DMKLROOT=${mkl}"
  ;

  installPhase = ''
    runHook preInstall

    mkdir -p $out/include
    cp -R lib bin $out/
    cp -R ../FECore \
      ../FEBioFluid \
      ../FEBioLib \
      ../FEBioMech \
      ../FEBioMix \
      ../FEBioOpt \
      ../FEBioPlot \
      ../FEBioXML \
      ../NumCore \
      $out/include

    runHook postInstall
  '';

  nativeBuildInputs = [ cmake ];
  buildInputs = [ boost eigen libxml2 mpi python3 python3.pkgs.numpy ]
   ++ lib.optional mklSupport mkl
  ;

  meta = {
    description = "FEBio Suite Solver";
    license = with lib.licenses; [ mit ];
    homepage = "https://febio.org/";
    platforms = lib.platforms.unix;
    maintainers = with lib.maintainers; [ Scriptkiddi ];
  };
}