blob: ac54ced75b1b9e6056a0e82ff7d9d5d9b2d6e0b9 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
|
{ lib
, stdenv
, fetchurl
# for passthru.tests
, python3
, perlPackages
, haskellPackages
, luaPackages
, ocamlPackages
}:
# Note: this package is used for bootstrapping fetchurl, and thus
# cannot use fetchpatch! All mutable patches (generated by GitHub or
# cgit) that are needed here should be included directly in Nixpkgs as
# files.
stdenv.mkDerivation rec {
pname = "expat";
version = "2.4.6";
src = fetchurl {
url = "https://github.com/libexpat/libexpat/releases/download/R_${lib.replaceStrings ["."] ["_"] version}/${pname}-${version}.tar.xz";
sha256 = "sha256-3lV5S3qbwhSFL9wHW+quzYVO/hNhWX5iaO6HlGlRKJs=";
};
outputs = [ "out" "dev" ]; # TODO: fix referrers
outputBin = "dev";
configureFlags = lib.optional stdenv.isFreeBSD "--with-pic";
outputMan = "dev"; # tiny page for a dev tool
doCheck = true; # not cross;
preCheck = ''
patchShebangs ./configure ./run.sh ./test-driver-wrapper.sh
'';
# CMake files incorrectly calculate library path from dev prefix
# https://github.com/libexpat/libexpat/issues/501
postFixup = ''
substituteInPlace $dev/lib/cmake/expat-${version}/expat-noconfig.cmake \
--replace "$"'{_IMPORT_PREFIX}' $out
'';
passthru.tests = {
inherit python3;
inherit (haskellPackages) hexpat;
inherit (perlPackages) XMLSAXExpat XMLParser;
inherit (luaPackages) luaexpat;
inherit (ocamlPackages) ocaml_expat;
};
meta = with lib; {
homepage = "https://libexpat.github.io/";
description = "A stream-oriented XML parser library written in C";
platforms = platforms.all;
license = licenses.mit; # expat version
};
}
|