blob: b839092228b3030cabfc4f55e038cc4a68176157 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
{ lib, stdenv, fetchurl, fetchpatch, fetchzip, perl, ncurses
# for tests
, aspell, glibc, runCommand
, searchNixProfiles ? true
}:
let
# Source for u-deva.cmap and u-deva.cset: use the Marathi
# dictionary like Debian does.
devaMapsSource = fetchzip {
name = "aspell-u-deva";
url = "https://ftp.gnu.org/gnu/aspell/dict/mr/aspell6-mr-0.10-0.tar.bz2";
sha256 = "1v8cdl8x2j1d4vbvsq1xrqys69bbccd6mi03fywrhkrrljviyri1";
};
in
stdenv.mkDerivation rec {
pname = "aspell";
version = "0.60.8";
src = fetchurl {
url = "mirror://gnu/aspell/aspell-${version}.tar.gz";
sha256 = "1wi60ankalmh8ds7nplz434jd7j94gdvbahdwsr539rlad8pxdzr";
};
patches = [
(fetchpatch {
# objstack: assert that the alloc size will fit within a chunk
name = "CVE-2019-25051.patch";
url = "https://github.com/gnuaspell/aspell/commit/0718b375425aad8e54e1150313b862e4c6fd324a.patch";
sha256 = "03z259xrk41x3j190gaprf3mqysyfgh3a04rjmch3h625vj95x39";
})
] ++ lib.optional searchNixProfiles ./data-dirs-from-nix-profiles.patch;
postPatch = ''
patch interfaces/cc/aspell.h < ${./clang.patch}
'';
nativeBuildInputs = [ perl ];
buildInputs = [ ncurses perl ];
doCheck = true;
preConfigure = ''
configureFlagsArray=(
--enable-pkglibdir=$out/lib/aspell
--enable-pkgdatadir=$out/lib/aspell
);
'';
# Include u-deva.cmap and u-deva.cset in the aspell package
# to avoid conflict between 'mr' and 'hi' dictionaries as they
# both include those files.
postInstall = ''
cp ${devaMapsSource}/u-deva.{cmap,cset} $out/lib/aspell/
'';
passthru.tests = {
uses-curses = runCommand "${pname}-curses" {
buildInputs = [ glibc ];
} ''
if ! ldd ${aspell}/bin/aspell | grep -q ${ncurses}
then
echo "Test failure: It does not look like aspell picked up the curses dependency."
exit 1
fi
touch $out
'';
};
meta = {
description = "Spell checker for many languages";
homepage = "http://aspell.net/";
license = lib.licenses.lgpl2Plus;
maintainers = [ ];
platforms = with lib.platforms; all;
};
}
|