blob: 3704332119e2ce7b4830669bb0b4d9f0bdccbe05 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
{ lib, mkDerivation, appstream, qtbase, qttools, nixosTests }:
# TODO: look into using the libraries from the regular appstream derivation as we keep duplicates here
mkDerivation {
pname = "appstream-qt";
inherit (appstream) version src;
outputs = [ "out" "dev" "installedTests" ];
buildInputs = appstream.buildInputs ++ [ appstream qtbase ];
nativeBuildInputs = appstream.nativeBuildInputs ++ [ qttools ];
mesonFlags = appstream.mesonFlags ++ [ "-Dqt=true" ];
patches = (appstream.patches or []) ++ lib.optionals (lib.versionOlder qtbase.version "5.14") [
# Fix darwin build for libsForQt5.appstream-qt
# Old Qt moc doesn't know about fancy C++14 features
# ../qt/component.h:93: Parse error at "UrlTranslate"
# Remove both this patch and related comment in default.nix
# once Qt 5.14 or later becomes default on darwin
./fix-build-for-qt-olderthan-514.patch
];
postFixup = ''
sed -i "$dev/lib/cmake/AppStreamQt/AppStreamQtConfig.cmake" \
-e "/INTERFACE_INCLUDE_DIRECTORIES/ s@\''${PACKAGE_PREFIX_DIR}@$dev@"
'';
passthru = appstream.passthru // {
tests = {
installed-tests = nixosTests.installed-tests.appstream-qt;
};
};
meta = appstream.meta // {
description = "Software metadata handling library - Qt";
};
}
|