blob: 773a0dde281f471d17f02ae5583e2769834ff1bc (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
|
{ callPackage
, fetchFromGitHub
, installShellFiles
, lib
, makeWrapper
, ocamlPackages
, removeReferencesTo
, stdenv
, writeScript
, z3
}:
let
version = "2023.09.03";
src = fetchFromGitHub {
owner = "FStarLang";
repo = "FStar";
rev = "v${version}";
hash = "sha256-ymoP5DvaLdrdwJcnhZnLEvwNxUFzhkICajPyK4lvacc=";
};
fstar-dune = ocamlPackages.callPackage ./dune.nix { inherit version src; };
fstar-ulib = callPackage ./ulib.nix { inherit version src fstar-dune z3; };
in
stdenv.mkDerivation {
pname = "fstar";
inherit version src;
nativeBuildInputs = [
installShellFiles
makeWrapper
removeReferencesTo
];
inherit (fstar-dune) propagatedBuildInputs;
dontBuild = true;
installPhase = ''
mkdir $out
CP="cp -r --no-preserve=mode"
$CP ${fstar-dune}/* $out
$CP ${fstar-ulib}/* $out
PREFIX=$out make -C src/ocaml-output install-sides
chmod +x $out/bin/fstar.exe
wrapProgram $out/bin/fstar.exe --prefix PATH ":" ${z3}/bin
remove-references-to -t '${ocamlPackages.ocaml}' $out/bin/fstar.exe
substituteInPlace $out/lib/ocaml/${ocamlPackages.ocaml.version}/site-lib/fstar/dune-package \
--replace ${fstar-dune} $out
installShellCompletion --bash .completion/bash/fstar.exe.bash
installShellCompletion --fish .completion/fish/fstar.exe.fish
installShellCompletion --zsh --name _fstar.exe .completion/zsh/__fstar.exe
'';
passthru.updateScript = writeScript "update-fstar" ''
#!/usr/bin/env nix-shell
#!nix-shell -i bash -p git gnugrep common-updater-scripts
set -eu -o pipefail
version="$(git ls-remote --tags git@github.com:FStarLang/FStar.git | grep -Po 'v\K\d{4}\.\d{2}\.\d{2}' | sort | tail -n1)"
update-source-version fstar "$version"
'';
meta = with lib; {
description = "ML-like functional programming language aimed at program verification";
homepage = "https://www.fstar-lang.org";
changelog = "https://github.com/FStarLang/FStar/raw/v${version}/CHANGES.md";
license = licenses.asl20;
maintainers = with maintainers; [ gebner pnmadelaine ];
mainProgram = "fstar.exe";
platforms = with platforms; darwin ++ linux;
};
}
|