nixpkgs/pkgs/by-name/yt/yt-dlg/package.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

{
  lib,
  python3,
  fetchFromGitHub,
  fetchPypi
}:
let
  python3Packages =
    (python3.override {
      packageOverrides = final: prev: {
        wxpython = prev.wxpython.overrideAttrs rec {
          version = "4.2.0";
          src = fetchPypi {
            pname = "wxPython";
            inherit version;
            hash = "sha256-ZjzrxFCdfl0RNRiGX+J093+VQ0xdV7w4btWNZc7thsc=";
          };
        };
      };
    }).pkgs;
in
python3Packages.buildPythonApplication rec {
  pname = "yt-dlg";
  version = "1.8.5";

  src = fetchFromGitHub {
    owner = "oleksis";
    repo = "youtube-dl-gui";
    rev = "v${version}";
    hash = "sha256-W1ZlArmM+Ro5MF/rB88me/PD79dJA4v188mPbMd8Kow=";
  };

  pyproject = true;
  build-system = with python3Packages; [
    setuptools
    wheel
  ];
  dependencies = with python3Packages; [
    pypubsub
    wxpython
  ];

  meta = {
    description = "A cross platform front-end GUI of the popular youtube-dl written in wxPython.";
    homepage = "https://oleksis.github.io/youtube-dl-gui";
    license = lib.licenses.unlicense;
    mainProgram = "yt-dlg";
    maintainers = with lib.maintainers; [ quantenzitrone ];
  };
}