1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
|
{ stdenv
, fetchurl
, coreutils
, makeWrapper
, sway-unwrapped
, installShellFiles
, wl-clipboard
, libnotify
, slurp
, grim
, jq
, python3Packages
}:
{
grimshot = stdenv.mkDerivation rec {
pname = "grimshot";
version = "2020-05-08";
rev = "b1d08db5f5112ab562f89564825e3e791b0682c4";
# master has new fixes and features, and a man page
# after sway-1.5 these may be switched to sway-unwrapped.src
bsrc = fetchurl {
url = "https://raw.githubusercontent.com/swaywm/sway/${rev}/contrib/grimshot";
sha256 = "1awzmzkib8a7q5s78xyh8za03lplqfpbasqp3lidqqmjqs882jq9";
};
msrc = fetchurl {
url = "https://raw.githubusercontent.com/swaywm/sway/${rev}/contrib/grimshot.1";
sha256 = "191xxjfhf61gkxl3b0f694h0nrwd7vfnyp5afk8snhhr6q7ia4jz";
};
dontBuild = true;
dontUnpack = true;
dontConfigure = true;
outputs = [ "out" "man" ];
nativeBuildInputs = [ makeWrapper installShellFiles ];
installPhase = ''
installManPage ${msrc}
install -Dm 0755 ${bsrc} $out/bin/grimshot
wrapProgram $out/bin/grimshot --set PATH \
"${stdenv.lib.makeBinPath [
sway-unwrapped
wl-clipboard
coreutils
libnotify
slurp
grim
jq
] }"
'';
doInstallCheck = true;
installCheckPhase = ''
# check always returns 0
if [[ $($out/bin/grimshot check | grep "NOT FOUND") ]]; then false
else
echo "grimshot check passed"
fi
'';
meta = with stdenv.lib; {
description = "A helper for screenshots within sway";
homepage = "https://github.com/swaywm/sway/tree/master/contrib";
license = licenses.mit;
platforms = platforms.all;
maintainers = with maintainers; [
sway-unwrapped.meta.maintainers
evils
];
};
};
inactive-windows-transparency = python3Packages.buildPythonApplication rec {
# long name is long
lname = "inactive-windows-transparency";
pname = "sway-${lname}";
version = sway-unwrapped.version;
src = sway-unwrapped.src;
format = "other";
dontBuild = true;
dontConfigure = true;
propagatedBuildInputs = [ python3Packages.i3ipc ];
installPhase = ''
install -Dm 0755 $src/contrib/${lname}.py $out/bin/${lname}.py
'';
meta = sway-unwrapped.meta // {
description = "It makes inactive sway windows transparent";
homepage = "https://github.com/swaywm/sway/tree/${sway-unwrapped.version}/contrib";
};
};
}
|