blob: b46e1c3508d7aae0e1663326ef1d279a9364913c (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
{ lib
, fetchFromSourcehut
, buildGoModule
, buildPythonPackage
, python
, srht
, setuptools
, pip
, pyyaml
, pythonOlder
, unzip
}:
let
version = "0.17.5";
gqlgen = import ./fix-gqlgen-trimpath.nix { inherit unzip; gqlgenVersion = "0.17.41"; };
src = fetchFromSourcehut {
owner = "~sircmpwn";
repo = "hub.sr.ht";
rev = version;
hash = "sha256-GbBxK3XE+Y6Jiap0Nxa8vk4Kv6IbcdSi4NN59AeKwjA=";
};
hubsrht-api = buildGoModule ({
inherit src version;
pname = "hubsrht-api";
modRoot = "api";
vendorHash = "sha256-wmuM0SxQbohTDaU8zmkw1TQTmqhOy1yAl1jRWk6TKL8=";
} // gqlgen);
in
buildPythonPackage rec {
inherit src version;
pname = "hubsrht";
pyproject = true;
disabled = pythonOlder "3.7";
postPatch = ''
substituteInPlace Makefile --replace "all: api" ""
'';
nativeBuildInputs = [
pip
setuptools
];
propagatedBuildInputs = [
srht
pyyaml
];
preBuild = ''
export PKGVER=${version}
export SRHT_PATH=${srht}/${python.sitePackages}/srht
'';
postInstall = ''
ln -s ${hubsrht-api}/bin/api $out/bin/hubsrht-api
'';
# Module has no tests
doCheck = false;
pythonImportsCheck = [
"hubsrht"
];
meta = with lib; {
homepage = "https://git.sr.ht/~sircmpwn/hub.sr.ht";
description = "Project hub service for the sr.ht network";
license = licenses.agpl3Only;
maintainers = with maintainers; [ eadwu christoph-heiss ];
};
}
|