blob: 512f0414f1c69d3837a06b854fb39f38cc134b1f (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
{ lib
, stdenv
, fetchurl
, unzip
, zlib
, enableUnfree ? false
}:
stdenv.mkDerivation rec {
pname = "glucose" + lib.optionalString enableUnfree "-syrup";
version = "4.2.1";
src = fetchurl {
url = "https://www.labri.fr/perso/lsimon/downloads/softwares/glucose-${version}.zip";
hash = "sha256-J0J9EKC/4cCiZr/y4lz+Hm7OcmJmMIIWzQ+4c+KhqXg=";
};
sourceRoot = "glucose-${version}/sources/${if enableUnfree then "parallel" else "simp"}";
postPatch = ''
substituteInPlace Main.cc \
--replace "defined(__linux__)" "defined(__linux__) && defined(__x86_64__)"
'';
nativeBuildInputs = [ unzip ];
buildInputs = [ zlib ];
makeFlags = [ "r" ];
installPhase = ''
runHook preInstall
install -Dm0755 ${pname}_release $out/bin/${pname}
mkdir -p "$out/share/doc/${pname}-${version}/"
install -Dm0755 ../{LICEN?E,README*,Changelog*} "$out/share/doc/${pname}-${version}/"
runHook postInstall
'';
meta = with lib; {
description = "Modern, parallel SAT solver (${if enableUnfree then "parallel" else "sequential"} version)";
homepage = "https://www.labri.fr/perso/lsimon/research/glucose/";
license = if enableUnfree then licenses.unfreeRedistributable else licenses.mit;
platforms = platforms.unix;
maintainers = with maintainers; [ gebner ];
};
}
|