1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
|
{ lib
, fetchbzr
, mkDerivation
, qmake
, qtserialport
, qtmultimedia
, qttools
, qtscript
}:
let
generic =
{ version
, release
, branch
, rev
, sha256
, extraPostPatch ? ""
, extraBuildInputs ? [ ]
, iconPath ? "resources/icons/simulide.png"
, installFiles ? ''
cp -r data examples $out/share/simulide
cp simulide $out/bin/simulide
''
}:
mkDerivation {
pname = "simulide";
version = "${version}-${release}";
src = fetchbzr {
url = "https://code.launchpad.net/~arcachofo/simulide/${branch}";
inherit rev sha256;
};
postPatch = ''
sed -i resources/simulide.desktop \
-e "s|^Exec=.*$|Exec=simulide|" \
-e "s|^Icon=.*$|Icon=simulide|"
# Note: older versions don't have REV_NO
sed -i SimulIDE.pro \
-e "s|^VERSION = .*$|VERSION = ${version}|" \
-e "s|^RELEASE = .*$|RELEASE = -${release}|" \
-e "s|^REV_NO = .*$|REV_NO = ${rev}|" \
-e "s|^BUILD_DATE = .*$|BUILD_DATE = ??-??-??|"
${extraPostPatch}
'';
preConfigure = ''
cd build_XX
'';
nativeBuildInputs = [
qmake
];
buildInputs = [
qtserialport
qtmultimedia
qttools
] ++ extraBuildInputs;
installPhase = ''
runHook preInstall
install -Dm644 ../resources/simulide.desktop $out/share/applications/simulide.desktop
install -Dm644 ../${iconPath} $out/share/icons/hicolor/256x256/apps/simulide.png
mkdir -p $out/share/simulide $out/bin
pushd executables/SimulIDE_*
${installFiles}
popd
runHook postInstall
'';
meta = {
description = "A simple real time electronic circuit simulator";
longDescription = ''
SimulIDE is a simple real time electronic circuit simulator, intended for hobbyist or students
to learn and experiment with analog and digital electronic circuits and microcontrollers.
It supports PIC, AVR, Arduino and other MCUs and MPUs.
'';
homepage = "https://simulide.com/";
license = lib.licenses.gpl3Only;
mainProgram = "simulide";
maintainers = with lib.maintainers; [ carloscraveiro tomasajt ];
platforms = [ "x86_64-linux" ];
};
};
in
{
simulide_0_4_15 = generic {
version = "0.4.15";
release = "SR10";
branch = "simulide_0.4.14"; # the branch name does not mach the version for some reason
rev = "291";
sha256 = "sha256-BBoZr/S2pif0Jft5wrem8y00dXl08jq3kFiIUtOr3LM=";
extraPostPatch = ''
# GCC 13 needs the <cstdint> header explicitly included
sed -i src/gpsim/value.h -e '1i #include <cstdint>'
sed -i src/gpsim/modules/watchdog.h -e '1i #include <cstdint>'
'';
extraBuildInputs = [ qtscript ];
iconPath = "resources/icons/hicolor/256x256/simulide.png"; # upstream had a messed up icon path in this release
installFiles = ''
cp -r share/simulide/* $out/share/simulide
cp bin/simulide $out/bin/simulide
'';
};
simulide_1_0_0 = generic {
version = "1.0.0";
release = "SR2";
branch = "1.0.0";
rev = "1449";
sha256 = "sha256-rJWZvnjVzaKXU2ktbde1w8LSNvu0jWkDIk4dq2l7t5g=";
extraBuildInputs = [ qtscript ];
};
simulide_1_1_0 = generic {
version = "1.1.0";
release = "RC1";
branch = "1.1.0";
rev = "1912";
sha256 = "sha256-bgRAqt7h2LtU2Ze6Jiz8APhyPcV15v4ofxIilIeZV9E=";
};
}
|