1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
{ lib
, stdenv
, fetchFromGitHub
, fetchpatch
, cmake
, perl
, wrapGAppsHook
, wrapQtAppsHook
, qtbase
, qtcharts
, qtpositioning
, qtmultimedia
, qtserialport
, qtwayland
, qtwebengine
, calcmysky
, qxlsx
, indilib
, libnova
, qttools
, exiv2
, nlopt
}:
stdenv.mkDerivation (finalAttrs: {
pname = "stellarium";
version = "23.4";
src = fetchFromGitHub {
owner = "Stellarium";
repo = "stellarium";
rev = "v${finalAttrs.version}";
hash = "sha256-rDqDs6sFaZQbqJcCRhY5w8sFM2mYHHvw0Ud2Niimg4Y=";
};
patches = [
# Compatibility with INDI 2.0 series from https://github.com/Stellarium/stellarium/pull/3269
(fetchpatch {
url = "https://github.com/Stellarium/stellarium/commit/31fd7bebf33fa710ce53ac8375238a24758312bc.patch";
hash = "sha256-eJEqqitZgtV6noeCi8pDBYMVTFIVWXZU1fiEvoilX8o=";
})
];
postPatch = lib.optionalString stdenv.isDarwin ''
substituteInPlace CMakeLists.txt \
--replace 'SET(CMAKE_INSTALL_PREFIX "''${PROJECT_BINARY_DIR}/Stellarium.app/Contents")' \
'SET(CMAKE_INSTALL_PREFIX "${placeholder "out"}/Applications/Stellarium.app/Contents")'
substituteInPlace src/CMakeLists.txt \
--replace "\''${_qt_bin_dir}/../" "${qtmultimedia}/lib/qt-6/"
'';
nativeBuildInputs = [
cmake
perl
wrapGAppsHook
wrapQtAppsHook
qttools
];
buildInputs = [
qtbase
qtcharts
qtpositioning
qtmultimedia
qtserialport
qtwebengine
calcmysky
qxlsx
indilib
libnova
exiv2
nlopt
] ++ lib.optionals stdenv.isLinux [
qtwayland
];
preConfigure = ''
export SOURCE_DATE_EPOCH=$(date -d 20${lib.versions.major finalAttrs.version}0101 +%s)
'' + lib.optionalString stdenv.isDarwin ''
export LC_ALL=en_US.UTF-8
'';
# fatal error: 'QtSerialPort/QSerialPortInfo' file not found
env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.isDarwin "-F${qtserialport}/lib";
dontWrapGApps = true;
postInstall = lib.optionalString stdenv.isDarwin ''
makeWrapper $out/Applications/Stellarium.app/Contents/MacOS/Stellarium $out/bin/stellarium
'';
preFixup = ''
qtWrapperArgs+=("''${gappsWrapperArgs[@]}")
'';
meta = {
description = "Free open-source planetarium";
homepage = "https://stellarium.org/";
license = lib.licenses.gpl2Plus;
platforms = lib.platforms.unix;
maintainers = with lib.maintainers; [ kilianar ];
};
})
|