1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
|
{ lib, stdenv, fetchFromGitLab, cmake, ninja, pkg-config, wrapGAppsHook
, glib, gtk3, gettext, libxkbfile, libX11, python3
, freerdp, libssh, libgcrypt, gnutls, vte
, pcre2, libdbusmenu-gtk3, libappindicator-gtk3
, libvncserver, libpthreadstubs, libXdmcp, libxkbcommon
, libsecret, libsoup_3, spice-protocol, spice-gtk, libepoxy, at-spi2-core
, openssl, gsettings-desktop-schemas, json-glib, libsodium, webkitgtk_4_1, harfbuzz
# The themes here are soft dependencies; only icons are missing without them.
, gnome
, withKf5Wallet ? stdenv.isLinux, libsForQt5
, withLibsecret ? stdenv.isLinux
, withVte ? true
}:
stdenv.mkDerivation (finalAttrs: {
pname = "remmina";
version = "1.4.31";
src = fetchFromGitLab {
owner = "Remmina";
repo = "Remmina";
rev = "v${finalAttrs.version}";
sha256 = "sha256-oEgpav4oQ9Sld9PY4TsutS5xEnhQgOHnpQhDesRFTeQ=";
};
nativeBuildInputs = [ cmake ninja pkg-config wrapGAppsHook ];
buildInputs = [
gsettings-desktop-schemas
glib gtk3 gettext libxkbfile libX11
freerdp libssh libgcrypt gnutls
pcre2
libvncserver libpthreadstubs libXdmcp libxkbcommon
libsoup_3 spice-protocol
spice-gtk
libepoxy at-spi2-core
openssl gnome.adwaita-icon-theme json-glib libsodium
harfbuzz python3
] ++ lib.optionals stdenv.isLinux [ libappindicator-gtk3 libdbusmenu-gtk3 webkitgtk_4_1 ]
++ lib.optionals withLibsecret [ libsecret ]
++ lib.optionals withKf5Wallet [ libsForQt5.kwallet ]
++ lib.optionals withVte [ vte ];
cmakeFlags = [
"-DWITH_VTE=${if withVte then "ON" else "OFF"}"
"-DWITH_TELEPATHY=OFF"
"-DWITH_AVAHI=OFF"
"-DWITH_KF5WALLET=${if withKf5Wallet then "ON" else "OFF"}"
"-DWITH_LIBSECRET=${if withLibsecret then "ON" else "OFF"}"
"-DFREERDP_LIBRARY=${freerdp}/lib/libfreerdp2${stdenv.hostPlatform.extensions.sharedLibrary}"
"-DFREERDP_CLIENT_LIBRARY=${freerdp}/lib/libfreerdp-client2${stdenv.hostPlatform.extensions.sharedLibrary}"
"-DFREERDP_WINPR_LIBRARY=${freerdp}/lib/libwinpr2${stdenv.hostPlatform.extensions.sharedLibrary}"
"-DWINPR_INCLUDE_DIR=${freerdp}/include/winpr2"
] ++ lib.optionals stdenv.isDarwin [
"-DHAVE_LIBAPPINDICATOR=OFF"
"-DWITH_CUPS=OFF"
"-DWITH_ICON_CACHE=OFF"
"-DWITH_WEBKIT2GTK=OFF"
];
env.NIX_CFLAGS_COMPILE = lib.optionalString stdenv.isDarwin (toString [
"-DTARGET_OS_IPHONE=0"
"-DTARGET_OS_WATCH=0"
]);
dontWrapQtApps = true;
preFixup = ''
gappsWrapperArgs+=(
--set-default SSL_CERT_DIR "/etc/ssl/certs/"
--prefix LD_LIBRARY_PATH : "${libX11.out}/lib"
${lib.optionalString stdenv.isDarwin ''
--prefix XDG_DATA_DIRS : "$XDG_ICON_DIRS"
''}
)
'';
meta = with lib; {
license = licenses.gpl2Plus;
homepage = "https://gitlab.com/Remmina/Remmina";
description = "Remote desktop client written in GTK";
maintainers = with maintainers; [ melsigl ryantm ];
platforms = platforms.linux ++ platforms.darwin;
};
})
|