1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
{ stdenv
, lib
, fetchurl
, dpkg
, autoPatchelfHook
, pango
, gtk3
, alsa-lib
, nss
, libXdamage
, libdrm
, mesa
, libxshmfence
, makeWrapper
, wrapGAppsHook
, gcc-unwrapped
, udev
}:
stdenv.mkDerivation rec {
pname = "bluemail";
version = "1.136.21-1884";
# Taking a snapshot of the DEB release because there are no tagged version releases.
# For new versions, download the upstream release, extract it and check for the version string.
# In case there's a new version, create a snapshot of it on https://archive.org before updating it here.
src = fetchurl {
url = "https://archive.org/download/blue-mail-1.136.21-1884/BlueMail.deb";
hash = "sha256-L9mCUjsEcalVxzl80P3QzVclCKa75So2sBG7KjjBVIc=";
};
nativeBuildInputs = [
autoPatchelfHook
makeWrapper
dpkg
wrapGAppsHook
];
buildInputs = [
pango
gtk3
alsa-lib
nss
libXdamage
libdrm
mesa
libxshmfence
udev
];
unpackCmd = "${dpkg}/bin/dpkg-deb -x $src debcontents";
dontBuild = true;
dontStrip = true;
dontWrapGApps = true;
installPhase = ''
mkdir -p $out/bin
mv opt/BlueMail/* $out
ln -s $out/bluemail $out/bin/bluemail
'';
makeWrapperArgs = [
"--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [ gcc-unwrapped.lib gtk3 udev ]}"
"--prefix PATH : ${lib.makeBinPath [ stdenv.cc ]}"
];
preFixup = ''
wrapProgram $out/bin/bluemail \
''${makeWrapperArgs[@]} \
''${gappsWrapperArgs[@]}
'';
meta = with lib; {
description = "Free, secure, universal email app, capable of managing an unlimited number of mail accounts";
homepage = "https://bluemail.me";
license = licenses.unfree;
platforms = platforms.linux;
sourceProvenance = with sourceTypes; [ binaryNativeCode ];
maintainers = with maintainers; [ onny ];
};
}
|