blob: c8c36049a2a40cad2c2970ec57527a5d31e89d2a (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
{ fetchFromGitHub, libcommuni, qtbase, qmake, lib, stdenv, wrapQtAppsHook }:
stdenv.mkDerivation rec {
pname = "communi";
version = "3.5.0";
src = fetchFromGitHub {
owner = "communi";
repo = "communi-desktop";
rev = "v${version}";
sha256 = "sha256-Ua5uXs2mEDrljvtIcdn1Kb+l5NJtRpB0AAbBz+DU+YE=";
fetchSubmodules = true;
};
nativeBuildInputs = [ qmake ]
++ lib.optional stdenv.isDarwin wrapQtAppsHook;
buildInputs = [ libcommuni qtbase ];
dontWrapQtApps = true;
preConfigure = ''
export QMAKEFEATURES=${libcommuni}/features
'';
qmakeFlags = [
"COMMUNI_INSTALL_PREFIX=${placeholder "out"}"
"COMMUNI_INSTALL_PLUGINS=${placeholder "out"}/lib/communi/plugins"
"COMMUNI_INSTALL_ICONS=${placeholder "out"}/share/icons/hicolor"
"COMMUNI_INSTALL_DESKTOP=${placeholder "out"}/share/applications"
"COMMUNI_INSTALL_THEMES=${placeholder "out"}/share/communi/themes"
(if stdenv.isDarwin
then [ "COMMUNI_INSTALL_BINS=${placeholder "out"}/Applications" ]
else [ "COMMUNI_INSTALL_BINS=${placeholder "out"}/bin" ])
];
postInstall = if stdenv.isDarwin then ''
# Nix qmake does not add the bundle rpath by default.
install_name_tool \
-add_rpath @executable_path/../Frameworks \
$out/Applications/Communi.app/Contents/MacOS/Communi
'' else ''
substituteInPlace "$out/share/applications/communi.desktop" \
--replace "/usr/bin" "$out/bin"
'';
preFixup = ''
rm -rf lib
'';
meta = with lib; {
description = "A simple and elegant cross-platform IRC client";
homepage = "https://github.com/communi/communi-desktop";
license = licenses.bsd3;
maintainers = with maintainers; [ hrdinka ];
platforms = platforms.all;
};
}
|