blob: e74595903b51e11ea44113c90a881d65297aa5b4 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
{ lib
, buildGoModule
, fetchFromGitHub
, installShellFiles
, k3sVersion ? null
}:
let
hasVPrefix = ver: (builtins.elemAt (lib.stringToCharacters ver) 0) == "v";
k3sVersionSet =
if k3sVersion != null then
if hasVPrefix k3sVersion then throw "k3sVersion should not have a v prefix" else true
else
false;
in
buildGoModule rec {
pname = "k3d";
version = "5.6.0";
src = fetchFromGitHub {
owner = "k3d-io";
repo = "k3d";
rev = "refs/tags/v${version}";
hash = "sha256-KIYwuDPkxhtQy989XW+DcI5NJPhfLP07mYUFc180Sdw=";
};
vendorHash = null;
nativeBuildInputs = [ installShellFiles ];
excludedPackages = [ "tools" "docgen" ];
ldflags =
let t = "github.com/k3d-io/k3d/v${lib.versions.major version}/version"; in
[ "-s" "-w" "-X ${t}.Version=v${version}" ] ++ lib.optionals k3sVersionSet [ "-X ${t}.K3sVersion=v${k3sVersion}" ];
preCheck = ''
# skip test that uses networking
substituteInPlace version/version_test.go \
--replace "TestGetK3sVersion" "SkipGetK3sVersion"
'';
postInstall = ''
installShellCompletion --cmd k3d \
--bash <($out/bin/k3d completion bash) \
--fish <($out/bin/k3d completion fish) \
--zsh <($out/bin/k3d completion zsh)
'';
doInstallCheck = true;
installCheckPhase = ''
runHook preInstallCheck
$out/bin/k3d --help
$out/bin/k3d --version | grep -e "k3d version v${version}" ${lib.optionalString k3sVersionSet "-e \"k3s version v${k3sVersion}\""}
runHook postInstallCheck
'';
env.GOWORK = "off";
meta = with lib; {
homepage = "https://github.com/k3d-io/k3d/";
changelog = "https://github.com/k3d-io/k3d/blob/v${version}/CHANGELOG.md";
description = "A helper to run k3s (Lightweight Kubernetes. 5 less than k8s) in a docker container";
longDescription = ''
k3s is the lightweight Kubernetes distribution by Rancher: rancher/k3s
k3d creates containerized k3s clusters. This means, that you can spin up a
multi-node k3s cluster on a single machine using docker.
'';
license = licenses.mit;
maintainers = with maintainers; [ kuznero jlesquembre ngerstle jk ricochet ];
platforms = platforms.linux ++ platforms.darwin;
};
}
|